我们特意将本文所讨论的范例应用程序设计得很简单。该应用程序在计算机的内存中创建一个数据库, 并在该数据库中创建一个表, 然后向数据库添加一些数据。单击 Load data (加载数据) 按钮, 然后检索数据, 并将其显示在屏幕上 (见图 1)。除了在单击按钮时加载数据以及在屏幕上显示这些数据之外, 不提供其它用户交互。特意这样做是为了使应用程序的重点完全放在数据库操作上。本范例应用程序演示 Adobe AIR 的以下功能:

• 使用异步执行模式连接至本地 SQL 数据库
• 异步创建和执行 SQL 语句:
  • 在数据库中创建表
  • 向数据库表中插入数据
  • 从数据库表中检索数据, 并在 Flex DataGrid 组件中显示这些数据

图 1。通过本范例应用程序可以从数据库中加载数据。

注意: 本范例应用程序按原样提供, 用于教学目的。

要求

若要充分利用本篇文章, 您需要以下软件和文件:

Adobe AIR

• 下载

Adobe Flex Builder 3

• 试用
• 购买

范例文件:

• SimpleDBExampleFlex.zip (ZIP, 815K)
• SimpleDBExampleFlex.air (AIR, 62K)

本范例应用程序包括以下文件:

• SimpleDBExampleFlex.mxml: 应用程序主文件 (Flex 的 MXML 格式), 其中包括本文所讨论的代码
• SimpleDBExampleFlex-app.xml: AIR 应用程序描述符文件
• AIR 图标文件范例

必备知识

应具备使用 Flex Builder 构建应用程序的一般经验。有关使用此快速入门指南的详细信息, 请参阅用 Flex 构建快速入门范例应用程序。

了解代码

注意: 对于文件的 MXML 代码所使用的全部 Flex 组件, 本文将不一一介绍。有关详细信息, 请参阅《Flex 3 语言参考》*。

连接至本地 SQL 数据库

应用程序加载完毕时将调用 init() 方法。在此方法中创建 SQLConnection 实例名 conn。 (在方法外声明变量 conn, 以使该变量对应用程序中的所有代码都可用。) 此 SQLConnection 对象建立到数据库的连接, 并由其它对象用于对该特定数据库执行操作。创建 SQLConnection 实例后, 即针对该实例注册一些事件侦听器, 以便在打开数据库连接 (或 openAsync() 操作失败) 时调用这些侦听器, 并调用 openAsync() 方法, 以异步执行模式打开到数据库的连接。

conn = new SQLConnection();
conn.addEventListener(SQLEvent.OPEN, openSuccess);
conn.addEventListener(SQLErrorEvent.ERROR, openFailure);
conn.openAsync(null);

在本例中, 将 null 作为参数传递至 openAsync() 方法, 表示运行时在计算机的内存中而非在磁盘位置中创建数据库。此外, 还可以 (使用 File 实例) 指定文件位置。然后, 运行时将打开该位置的数据库文件 (如果文件不存在, 则首先创建该文件)。执行该任务的代码如下所示:

var dbFile:File = File.applicationStorageDirectory.resolvePath("DBSample.db");
conn.openAsync(dbFile);

File.applicationStorageDirectory 指向 AIR 应用程序的存储目录, 该目录的定义对于每个 AIR 应用程序都是独一无二的。

假定 openAsync() 操作成功并且打开了数据库连接, 则调用 openSuccess() 方法。该方法只是执行解除事件侦听器注册关系的清理操作, 并调用 createTable() 方法, 在数据库中创建表。

在数据库中创建表

createTable() 方法使用 SQLStatement 实例, 针对在 init() 方法中打开的数据库执行一条 SQL 命令。这条具体的 SQL 命令在数据库中创建一个名为“employees”的表, 其中包括四列。以下将代码分解, 分别介绍各段代码的作用:

• 创建名为 createStmt 的 SQLStatement 实例:

  createStmt = new SQLStatement();

• 指定对通过 SQLConnection 实例 conn 连接的数据库将执行语句:

  createStmt.sqlConnection = conn;

• 定义用于创建数据库表的 SQL 语句文本。将表命名为“employees”。该表包含四列: “empId”、“firstName”、“lastName”和“salary”。

  var sql:String = "";
  sql += "CREATE TABLE IF NOT EXISTS employees (";
  sql += "	empId	INTEGER PRIMARY KEY AUTOINCREMENT,";
  sql += "	firstName	TEXT,";
  sql += "	lastName	TEXT,";
  sql += "	salary	NUMERIC CHECK (salary >= 0) DEFAULT 0";
  sql += ")";
  createStmt.text = sql;

• 注册事件侦听器, 用于指定语句执行完毕 (createResult) 或失败 (createError) 时调用的方法:

  createStmt.addEventListener(SQLEvent.RESULT, createResult);
  createStmt.addEventListener(SQLErrorEvent.ERROR, createError);

• 执行语句:

  createStmt.execute();

假定语句成功运行, 则创建“employees”表, 并调用 createResult() 方法。该方法删除已注册的侦听器, 并调用 addData() 方法以执行过程中的下一步: 向新创建的表中添加数据。

向数据库表中插入数据

与 createTable() 方法一样, addData() 方法也创建 SQLStatement, 在本例中是为了向数据库的“employees”表中插入一行数据。应用程序使用两个不同的 SQLStatement 实例 (insertStmt 和 insertStmt2) 插入两行数据:

insertStmt = new SQLStatement();
insertStmt.sqlConnection = conn;
var sql:String = "";
sql += "INSERT INTO employees (firstName, lastName, salary) ";
sql += "VALUES ('Bob', 'Smith', 8000)";
insertStmt.text = sql;
 
insertStmt.addEventListener(SQLEvent.RESULT, insertResult);
insertStmt.addEventListener(SQLErrorEvent.ERROR, insertError);
 
insertStmt.execute();
 
insertStmt2 = new SQLStatement();
insertStmt2.sqlConnection = conn;
var sql2:String = "";
sql2 += "INSERT INTO employees (firstName, lastName, salary) ";
sql2 += "VALUES ('John', 'Jones', 8200)";
insertStmt2.text = sql2;
 
insertStmt2.addEventListener(SQLEvent.RESULT, insertResult);
insertStmt2.addEventListener(SQLErrorEvent.ERROR, insertError);
 
insertStmt2.execute();

注意, 由于执行第二条语句不依赖于第一条语句的结果, 因此在调用第一个实例的 execute() 方法之后立即创建第二个 SQLStatement 实例, 并调用其 execute() 方法。 (而不是等待第一条 INSERT 语句的 result 事件后再执行第二条语句。) 运行时将这两条语句排队, 在第一条语句完成后立即执行第二条语句。

唯一的复杂因素是代码需要确定两条语句都已完成, 然后才开始从数据库中检索数据。为此, 在 (触发每个 SQLStatement 的 result 事件时调用的) insertResult() 方法中, 应用程序确定哪条语句执行完毕, 然后检查是否两条语句都已执行完毕。如果都已执行完毕, 则将状态栏文本 (status) 更新为“Ready to load data” (已准备好加载数据), 此时应用程序已准备好从数据库中检索数据以及在屏幕上显示这些数据:

private function insertResult(event:SQLEvent):void
{
    var stmt:SQLStatement = event.target as SQLStatement;
    stmt.removeEventListener(SQLEvent.RESULT, insertResult);
    stmt.removeEventListener(SQLErrorEvent.ERROR, insertError);
    if (stmt == insertStmt)
    {
        insert1Complete = true;
    }
    else
    {
        insert2Complete = true;
    }
    
    if (insert1Complete && insert2Complete)
    {
        status = "Ready to load data";
    }
}

从数据库表中检索数据

与创建表并在其中插入数据一样, 从表中检索数据也是通过类似方法来实现的: 创建 SQLStatement 实例, 并将 SQL SELECT 语句作为 SQLStatement 实例的 text 属性。以下代码来自 getData() 方法, 这段代码创建并执行从“employees”表中检索所有行的 SELECT 语句:

selectStmt = new SQLStatement();
selectStmt.sqlConnection = conn;
var sql:String = "SELECT empId, firstName, lastName, salary FROM employees";
selectStmt.text = sql;
 
selectStmt.addEventListener(SQLEvent.RESULT, selectResult);
selectStmt.addEventListener(SQLErrorEvent.ERROR, selectError);
 
selectStmt.execute();

正如代码中所指, SELECT 语句执行完毕时将调用 selectResult() 方法。在 selectResult() 中, 通过调用 SQLStatement 实例的 getResult() 方法, 访问由 SELECT 语句检索的结果数据。调用 getResult() 将返回存储在变量 result 中的 SQLResult 实例；实际的各行结果包含在该变量的 data 属性的一个数组中。通过将其 (即 result.data 属性) 设置为 resultsGrid 数据网格的 dataProvider 属性, 在名为 resultsGrid 的 Flex DataGrid 控件中显示这些结果:

private function selectResult(event:SQLEvent):void
{
    // ... 清理 ...
    
    var result:SQLResult = selectStmt.getResult();
    resultsGrid.dataProvider = result.data;
}

关于作者