The application is intentionally simple. It creates a database in the computer's memory, creates a table in that database, and adds some data to the database. Clicking on the Load data button then retrieves the data and displays it on the screen (see Figure 1). Other than loading data when the button is clicked and displaying it on the screen, there is no additional user interaction available. This is intentional, to focus the application entirely on the database operations. This sample application demonstrates the following Adobe AIR features:

• Connecting to a local SQL database using synchronous execution mode
• Creating and executing SQL statements synchronously:
  • Creating a table in the database
  • Inserting data into the database table
  • Retrieving data from the database table and displaying that data in a Flex DataGrid component

Figure 1. This sample application enables you to load data from a database.

Note: This is a sample application provided, as is, for instructional purposes.

Requirements

To make the most of this article, you need the following software and files:

Adobe AIR

• Download

Adobe Flex Builder or Flex SDK (version 3 or later)

• Try Flex Builder
• Buy Flex Builder
• Get Flex SDK

Sample files:

• SimpleSyncDBExampleFlex.zip (ZIP, 102K)
• SimpleSyncDBExampleFlex.air (AIR, 551K)

This sample application includes the following files:

• SimpleSyncDBExampleFlex.mxml: The main application file in MXML for Flex; includes the code discussed in this article
• SimpleSyncDBExampleFlex-app.xml: The AIR application descriptor file
• Sample AIR icon files

Important

The application descriptor file, SimpleSyncDBExampleFlex-app.xml, uses the AIR 1.0 namespace. If you are compiling the application using Flex Builder 3.0.2 or Flex SDK 3.2 or later, edit the file to use the AIR 1.5 namespace:

xmlns="http://ns.adobe.com/air/application/1.5"

Otherwise, you will not be able to test or package the application.

Prerequisite knowledge

General experience of building applications with Flex Builder is suggested. For more details on getting started with this Quick Start, refer to Building the Quick Start sample applications with Flex.

Understanding the code

Note: This article does not describe all of the Flex components used in the MXML code for the file. For more information, see the Flex 3 Language Reference.

Connecting to a local SQL database

The init() method is called when the application finishes loading. Within this method, a SQLConnection instance name conn is created. (The variable conn is declared outside the method so that it is available to all the code in the application.) This SQLConnection object establishes the connection to a database, and is used by other objects to perform operations on that specific database. Once the SQLConnection instance is created, the open() method is called to open the connection to the database in synchronous execution mode.

try
{
    conn.open(null);
}
catch (error:SQLError)
{
    status = "Error opening database";
    trace("error.message:", error.message);
    trace("error.details:", error.details);
    return;
}
 
createTable();

In this case null is passed as an argument to the open() method, indicating that the runtime will create a database in the computer's memory rather than in a disk location. Alternatively, you could specify a file location (using a File instance). The runtime would then open the database file at that location (creating it first if it doesn't exist). The code to do that would look like this:

var dbFile:File = File.applicationStorageDirectory.resolvePath("DBSample.db");
conn.open(dbFile);

File.applicationStorageDirectory points to the AIR application store directory, which is uniquely defined for each AIR application.

Because the open() call is surrounded in a try..catch block, if the call fails the init() method returns and execution ends. Assuming the open() operation succeeds and the database connection opens, the createTable() method is called to do the work of creating a table in the database.

Creating a table in the database

The createTable() method uses a SQLStatement instance to execute a SQL command against the database that was opened in the init() method. The specific SQL command creates a table in the database named "employees," with four columns. Here is a breakdown of the code and what it does:

• Creates a SQLStatement instance named createStmt:

  createStmt = new SQLStatement();

• Specifies that the statement executes on the database that's connected through the SQLConnection instance conn:

  createStmt.sqlConnection = conn;

• Defines the SQL statement text to create a database table. The table is named "employees." It has four columns: "empId," "firstName," "lastName," and "salary."

  var sql:String = "";
  sql += "CREATE TABLE IF NOT EXISTS employees (";
  sql += "	empId	INTEGER PRIMARY KEY AUTOINCREMENT,";
  sql += "	firstName	TEXT,";
  sql += "	lastName	TEXT,";
  sql += "	salary	NUMERIC CHECK (salary >= 0) DEFAULT 0";
  sql += ")";
  createStmt.text = sql;

• Executes the statement (surrounded in a try..catch block to determine if an error occurs):

  createStmt.execute();

Assuming that the statement runs successfully, the "employees" table is created and the addData() method is called to perform the next step in the process, adding data into the newly created table.

Inserting data into the database table

Like the createTable() method, the addData() method creates a SQLStatement, in this case to insert a row of data into the "employees" table in the database. The application inserts two rows of data, using two different SQLStatement instances (insertStmt and insertStmt2):

insertStmt = new SQLStatement();
insertStmt.sqlConnection = conn;
var sql:String = "";
sql += "INSERT INTO employees (firstName, lastName, salary) ";
sql += "VALUES ('Bob', 'Smith', 8000)";
insertStmt.text = sql;
 
insertStmt2 = new SQLStatement();
insertStmt2.sqlConnection = conn;
var sql2:String = "";
sql2 += "INSERT INTO employees (firstName, lastName, salary) ";
sql2 += "VALUES ('John', 'Jones', 8200)";
insertStmt2.text = sql2;
 
try
{
    insertStmt.execute();
    insertStmt2.execute();
}
catch (error:SQLError)
{
    status = "Error inserting data";
    trace("INSERT error:", error);
    trace("error.message:", error.message);
    trace("error.details:", error.details);
    return;
}
 
status = "Ready to load data";

If both statements finish executing without errors, the status bar text (status) is updated to read "Ready to load data" and the application is ready to retrieve the data from the database and display it on the screen.

Retrieving data from the database table

Like creating a table and inserting data into the table, retrieving data from a table is carried out by creating a SQLStatement instance with a SQL SELECT statement as the SQLStatement instance's text property. The following code, from the getData() method, creates and executes the SELECT statement that retrieves all the rows from the "employees" table:

selectStmt = new SQLStatement();
selectStmt.sqlConnection = conn;
var sql:String = "SELECT empId, firstName, lastName, salary FROM employees";
selectStmt.text = sql;
 
try
{
    selectStmt.execute();
}
catch (error:SQLError)
{
    status = "Error loading data";
    trace("SELECT error:", error);
    trace("error.message:", error.message);
    trace("error.details:", error.details);
    return;
}

When the SELECT statement finishes executing the runtime continues executing the following code from the getData() method. The result data that is retrieved by the SELECT statement is accessed by calling the SQLStatement instance's getResult() method. Calling getResult() returns a SQLResult instance that is stored in the variable result; the actual result rows are contained in an array in its data property. The results are displayed in the Flex DataGrid control named resultsGrid by setting it (that is, the result.data property) as the resultsGrid data grid's dataProvider property:

status = "Data loaded";
var result:SQLResult = selectStmt.getResult();
resultsGrid.dataProvider = result.data;

About the author