Getting a Handle on Web Services in Macromedia Flash MX Professional 2004

<?php

// Grab values from REQUEST and unserialize
$wsdl = unserialize(urldecode($_REQUEST['wsdl']));
$methodName = unserialize(urldecode($_REQUEST['methodName']));
$paramArray = array_reverse(unserialize(urldecode(stripslashes($_REQUEST['paramArray']))));

// Include nusoap.php file.
require_once('nusoap.php');

// Define new object via nusoap.php and specify location of WSDL
$soapclient = new soapclient($wsdl,'wsdl');

// Set timeouts, nusoap default is 30
$soapclient->timeout = 500;
$soapclient->response_timeout = 500;

// Call the web service operation/method and accept the result
$SOAPResult = $soapclient->call($methodName,$paramArray);

// Serialize the result before sending back to Flash
$serializedResult = utf8_encode(serialize($SOAPResult));

// Send result back to Flash
print "&myResult=" . urlencode($serializedResult);

?>

// import the Serializer class
import it.sephiroth.Serializer;

class com.ws.GenericProxy {

	// object to un/serialize data before sending/receiving to/from PHP
	private var serial:Serializer;
	
	// LoadVars object to send and receive the data
	private var lv:LoadVars;
	
	// WSDL for the web service
	public var wsdl:String;
	
	// unserialized result sent back from web service via PHP
	public var myResult:Object;
	
	// function that is called when result comes back from PHP;
	// defined by user
	public var onResult:Function;
	
	// constructor
	function GenericProxy(wsdlURI) {
		wsdl = wsdlURI;
	}
	
	// method that calls the web service via PHP
	public function makeMethodCall(methodName, paramArray) {

		// define new Serializer object
		serial = new Serializer();

		// define the LoadVars object
		lv = new LoadVars();

		// prepare the variables that the LoadVars object will pass
		// to GenericProxy.php by defining and serializing them
		lv.wsdl = escape(serial.serialize(wsdl));
		lv.methodName = escape(serial.serialize(methodName));
		lv.paramArray = escape(serial.serialize(paramArray));
	
		// create reference to class instance to be available
		// inside the LoadVars object
		lv.gp = this;
	
		// function that is called when the LoadVars object
		// receives data back from GenericProxy.php
		lv.onLoad = function(success) {
			if (success) {
				
				// invoke onResult method and pass unserialized result to it
				this.gp.onResult(this.gp.serial.unserialize(this.myResult));
				
			} else {
				
				// The data didn't load right.
				// Note: this has nothing to do with the actual web service
				trace("LoadVars failure");
			
			}
		};

		// call GenericProxy.php to pass the LoadVars variables
		// to it
		lv.sendAndLoad("GenericProxy.php", lv, "POST"); 
	}
}

lv.sendAndLoad("GenericProxy.php", lv, "POST"); 

lv.sendAndLoad("http://localhost/GenericProxy.php", lv, "POST");

// import the generic proxy class
import com.ws.GenericProxy;
// import the controls classes so we can add UI components
// at runtime
import mx.controls.*;

// define the location of the WSDL
wsdl = "http://java.rus.uni-stuttgart.de/quiz/quiz.wsdl";
// create a new GenericProxy object
var proxy:GenericProxy = new GenericProxy(wsdl);

// set global depth that will be incremented every time
// a new visual element is added dynamically
_global.MAXDEPTH = 5;
// create a reference to the timeline
var host:MovieClip = this;
// create an array with possible answers
var answerRefs:Array = ["A", "B", "C", "D"];
// set some spacing variables for laying out the content
var xSpacing:Number = 20;
var xSpot:Number = 20;
var ySpacing:Number = 50;
var ySpot:Number = 50;
// initiate two more variables
var answerCount:Number;
var questionRef:Object;

// initiate the app by getting the first question
getQuestion();

// what to do when the "new question" button is clicked
questionButton.onRelease = function() {
	cleanUp();
	getQuestion();
}

// what to do when the "check answer" button is clicked
checkButton.onRelease = function() {
	checkAnswer();
}

// get a new question from the database
function getQuestion() {
	// disable all UI elements
	disable();
	// make a method call to getRandomQuestion() 
	// via the proxy service object
	proxy.makeMethodCall("getRandomQuestion");
	// assign a method to the proxy's onResult
	proxy.onResult = getQuestionResult;
}

// function that is called when web service result arrives
function getQuestionResult(WSResult:Object) {
	answerCount= 0;
	ySpot = 50;
	statusText.text = "";
	questionRef = WSResult;
	// create a text field for the question
	host.createTextField("q", MAXDEPTH++, xSpot, ySpot, 250, 50);
	host.q.multiline = true;
	host.q.wordWrap = true;
	host.q.text = questionRef.question;
	ySpot += 50;
	for (var i in questionRef) {
		if (i.substr(0, 6) == "answer") {
			// create a radio button for each multiple-choice answer
			host.createClassObject(RadioButton, "rb"+answerCount, MAXDEPTH++);
			var rb = host["rb"+answerCount];
			rb.groupName = "answerGroup";
			if (answerCount == 0) {
				rb.selected = true;
			}
			rb._x = xSpot;
			rb._y = ySpot+3;
			// create a text field for each answer
			host.createTextField("answer"+answerCount, MAXDEPTH++, xSpot+xSpacing, ySpot, 200, 20);
			var a = host["answer"+answerCount];
			a.text = questionRef["answer"+answerRefs[answerCount]];
			// create a horizontal rule after each answer
			host.attachMovie("hr", "hr"+answerCount, MAXDEPTH++);
			var hr = host["hr"+answerCount];
			hr._x = xSpot;
			hr._y = a._y+a._height+10;
			ySpot += ySpacing;
			answerCount++;
		}
	}
	// re-enable UI elements
	enable();
}

// check the answer the user selected
function checkAnswer() {
	disable();
	// prepare the parameters to be sent to web service
	var id = questionRef.id;
	var guessedAnswer = answerRefs[host.answerGroup.selection._name.substr(2, 1)];
	parameters = [id, guessedAnswer];
	// make the web service call to checkCorrectAnswerById(),
	// and pass the parameters
	proxy.makeMethodCall("checkCorrectAnswerById", parameters);
	// assign the onResult method for the proxy
	proxy.onResult = checkAnswerResult;
}

// function that is called when result comes back from call
// to checkCorrectAnswerById()
function checkAnswerResult(WSResult:String) {
	statusText.text = "";
	// decide whether to display "correct" or "incorrect" visual
	if (WSResult == true) {
		feedback.gotoAndStop("correct");
	} else {
		feedback.gotoAndStop("incorrect");
	}
	enable();
}

// cleans up question and answers when a new one is requested
function cleanUp() {
	for (var i = 0; i < answerCount; i++) {
		host["rb" + i].removeMovieClip();
		host["answer" + i].removeTextField();
		host["hr" + i].removeMovieClip();
	}
	host.q.removeTextField();
}

// two functions to en/disable UI elements
function enable() {
	checkButton.enabled = true;
	questionButton.enabled = true;
}

function disable() {
	checkButton.enabled = false;
	questionButton.enabled = false;
	lilMessage = "<talking to web service, please wait>";
	statusText.text = lilMessage.toUpperCase();
	feedback.gotoAndStop(1);
}

wsdl = "http://java.rus.uni-stuttgart.de/quiz/quiz.wsdl";
var proxy:GenericProxy = new GenericProxy(wsdl);
proxy.makeMethodCall("getRandomQuestion");
proxy.onResult = getQuestionResult;