ColdFusion MX
目 次 > CFML リファレンス > ColdFusion 関数 > CreateODBCDateTime O

CreateODBCDateTime

ODBC 日付および時刻オブジェクトを作成します。

ODBC タイムスタンプ形式の日付/時刻オブジェクト

日付および時刻関数

CreateODBCDateTime(date)

CreateDateTime、CreateODBCDate、CreateODBCTime、Now

パラメータ

説明

date

西暦 100 ～ 9999 年の期間の日付/時刻オブジェクトです。

日付/時刻値を文字列として渡すときは、その値を引用符で囲む必要があります。 引用符で囲まない場合、その値は日付/時刻オブジェクトの数値表現として解釈されます。

<!--- この例は、CreateDate、CreateDateTime、CreateODBCDate および CreateODBCDateTime の使用方法を示しています。 --->
<h3>CreateODBCDateTime の例</h3>

<CFIF IsDefined("form.hour")>
CreateDateTime で生成された日付値:
<CFSET yourDate = CreateDateTime(form.year, form.month, form.day,
form.hour,form.minute, form.second)>
<cfoutput>
<ul>
   <li>CreateDate で設定した形式 : #CreateDate(form.year, form.month,form.day)#
   <li>CreateDateTime で設定した形式 : #CreateDateTime(form.year,form.month,
      form.day,form.hour,form.minute,form.second)#
   <li>CreateODBCDate で設定した形式 : #CreateODBCDate(yourDate)#
   <li>CreateODBCDateTime で設定した形式 : #CreateODBCDateTime(yourDate)#
</ul>
<p>同じ値を、DateFormat で形式設定できます。
<ul>
   <li>CreateDate および DateFormat で設定した形式 :  
      #DateFormat(CreateDate(form.year,form.month,form.day), "mmm-dd-yyyy")#
   <li>CreateDateTime および DateFormat で設定した形式 :  
      #DateFormat(CreateDateTime(form.year,form.month,form.day,
      form.hour,form.minute,form.second))#
   <li>CreateODBCDate および DateFormat で設定した形式 :  
      #DateFormat(CreateODBCDate(yourDate), "mmmm d, yyyy")#
   <li>CreateODBCDateTime および DateFormat で設定した形式 :  
      #DateFormat(CreateODBCDateTime(yourDate), "d/m/yy")#
</ul>
</cfoutput>
</CFIF>
<CFFORM ACTION="createodbcdatetime.cfm" METHOD="POST">
<p>年、月、および日を整数で入力します。
<PRE>

年       <CFINPUT
         TYPE="Text"  NAME="year" VALUE="1998" VALIDATE="integer" REQUIRED="Yes">

月       <CFINPUT 
         TYPE="Text" NAME="month"  VALUE="6"  RANGE="1,12"
         MESSAGE="月 (1 ～ 12) を入力してください。" VALIDATE="integer" REQUIRED="Yes">

日       <CFINPUT TYPE="Text" NAME="day" VALUE="8" RANGE="1,31" 
         MESSAGE="日 (1 ～ 31) を入力してください。" VALIDATE="integer" REQUIRED="Yes">

時       <CFINPUT TYPE="Text" NAME="hour" VALUE="16" RANGE="0,23" 
         MESSAGE="時 (0 ～ 23) を入力してください。" VALIDATE="integer" REQUIRED="Yes">
         
分       <CFINPUT TYPE="Text" NAME="minute" VALUE="12" RANGE="0,59" 
         MESSAGE="分 (0 ～ 59) を入力してください。" VALIDATE="integer" REQUIRED="Yes">
         
秒       <CFINPUT TYPE="Text" NAME="second" VALUE="0" RANGE="0,59" 
         MESSAGE="秒 (0 ～ 59) を入力してください。" VALIDATE="integer" REQUIRED="Yes">
</PRE>
<p><INPUT TYPE="Submit" NAME=""> <INPUT TYPE="RESET">
</cfform>
目 次 > CFML リファレンス > ColdFusion 関数 > CreateODBCDateTime O