IsXmlNode

説明

関数パラメータが XML ドキュメントオブジェクトのノードであるかどうかを調べます。

戻り値

関数の引数が XML ドキュメントオブジェクトのノードである場合は true、そうでない場合は false。

カテゴリ

決定関数、XML 関数

関数のシンタックス

IsXmlNode(value)

関連項目

IsXML、IsXmlAttribute、IsXmlDoc、IsXmlElem、IsXmlRoot、XmlGetNodeType、XmlSearch、XmlValidate、『ColdFusion MX 開発ガイド』のXML および WDDX の使用

ヒストリ

ColdFusion MX 7: この関数が追加されました。

パラメータ

使用方法

この関数は、XML ドキュメントオブジェクトの次のコンポーネントについて true を返します。

• ドキュメントオブジェクト
• オブジェクト内の要素
• 要素の XmlNodes 配列内の XmlNode オブジェクト

この関数は、XmlSearch 関数によって返された XML ノードオブジェクトに対しても true を返します。ただし、XmlText、XmlComment、XmlCdata、XmlAttributes 配列 (または個々の XML 属性) など、要素内のほとんどのエントリに対しては true を返しません。

例

次の例では、XML ドキュメントオブジェクト、要素、オブジェクト内の属性、および XmlSearch 関数が返す属性がノードであるかどうかをテストします。

<!--- XML ドキュメントオブジェクトを作成 --->
<cfxml variable="xmlobject">
<?xml version="1.0" encoding="UTF-8"?>
<order id="4323251">
   <customer firstname="Philip" lastname="Cramer" accountNum="21"/>
   <items>
      <item id="43">
         <quantity>1</quantity>
         <unitprice>15.95</unitprice>
      </item>
   </items>
</order>
</cfxml>

<!--- XmlSearch を使用して属性ノードを取得 --->
<cfset lastnames = XmlSearch(xmlobject, '//@lastname')>

<!--- オブジェクトをテストして XML ノードかどうかを確認 --->
<cfoutput>
<h3>これらは XML ノードですか?</h3>
xmlobject:#IsXmlNode(xmlobject)#<br>
<!--- アイテム要素 --->
xmlobject.order.items:#IsXmlNode(xmlobject.order.items)#<br>
<!--- オーダー要素の ID 属性。DOM ノードではなく、単純な変数です。--->
xmlobject.order.XmlAttributes.id: 
   #IsXmlNode(xmlobject.order.XmlAttributes.id)#<br>
XmlSearch が返す lastnames[1]: 
#isXmlNode(lastnames[1])#
</cfoutput>

ColdFusion MX 7 | ColdFusion MX 6.1 | ColdFusion MX* | ColdFusion 5* | フォーラム* | デベロッパーセンター | サポート情報 | バグ報告

バージョン7