BinaryDecode

説明

文字列をバイナリオブジェクトに変換します。文字列形式にエンコードされたバイナリデータをバイナリオブジェクトに戻すときに使用します。

戻り値

バイナリオブジェクト

カテゴリ

変換関数、文字列関数

関数のシンタックス

BinaryDecode(string, binaryencoding)

関連項目

BinaryEncode、CharsetEncode、CharsetDecode

ヒストリ

ColdFusion MX 7: この関数が追加されました。

パラメータ

使用方法

この関数を使用して、バイナリ形式でエンコードされた文字列表記のバイナリデータを、バイナリオブジェクトに変換し、アプリケーションで使用できるようにします。バイナリデータは、HTTP や SMTP などの多くのインターネットプロトコルで転送することやデータベースで保管することが可能な文字列としてエンコードされることがよくあります。

ToBinary(base64data) 関数ではなく、BinaryDecode 関数を使用して、すべての新規アプリケーションで、Base64 でエンコードされたデータをバイナリデータに変換することをお勧めします。

バイナリデータの処理の詳細については、次の各ページを参照してください。

• バイナリデータをファイルにロードする方法および読み込む方法については、cffile を参照してください。
• バイナリデータをシリアル化およびシリアル化解除する方法については、cfwddx を参照してください。
• 変数がバイナリ形式がどうかをチェックする方法については、IsBinary を参照してください。
• バイナリオブジェクトの長さを調べる方法については、Len を参照してください。

例

次の例では、GIF ファイルをバイナリデータとして読み込み、バイナリ形式でエンコードされた文字列に変換した後に、このエンコードされたデータをバイナリデータに戻し、結果をファイルに書き込みます。エンコードされた文字列およびイメージを出力ファイルに表示します。

<h3>バイナリエンコードの変換の例</h3>

<!--- フォームが送信された場合、次の処理を実行します。 --->
<cfif IsDefined("Form.binEncoding")>

   <!--- バイナリデータファイルを読み込みます。 --->
   <cffile action="readbinary" file="C:¥CFusionMX7¥wwwroot¥CFIDE¥administrator¥images¥help.gif" variable="binimage">

   <!--- 読み込みデータをバイナリエンコードで変換した後にバイナリデータに戻します。 --->
   <cfscript>
      binencode=BinaryEncode(binimage, Form.binEncoding);
      bindecode=BinaryDecode(binencode, Form.binEncoding);
   </cfscript>

   <!---  変換の結果をファイルに書き込みます。 --->
   <cffile action="write" file="C:¥temp¥help.gif" output="#bindecode#" addnewline="No" >

   <!--- 結果を表示します。 --->
   <cfoutput>
      <p><b>バイナリエンコード :</b> #Form.binEncoding#</p>
      
      <p><b>BinaryEncode によりバイナリ形式でエンコードされた文字列に変換されたイメージ
         </b><br>
         #binencode#</p>
      <p><b>BinaryDecode を使用してバイナリに戻された後にファイルに
         書き込まれたイメージ</b><br>
      <img src="C:¥temp¥help.gif"><br> 
   </cfoutput>
</cfif>

<!--- 入力形式 --->
<form action="#CGI.SCRIPT_NAME#" method="post">
   <b>バイナリエンコードを選択</b><br>
   <select size="1" name="binEncoding" >
      <option selected>UU</option>
      <option>Base64</option>
      <option>Hex</option>
   </select><br>
   <br>
   <input type = "Submit" value = "convert my data">
</form>

ColdFusion MX 7 | ColdFusion MX 6.1 | ColdFusion MX* | ColdFusion 5* | フォーラム* | デベロッパーセンター | サポート情報 | バグ報告

バージョン7