cfcollection

説明

Verity 検索エンジンのコレクションを作成および管理します。

カテゴリ

シンタックス

<cfcollection
   action = "action"
   collection = "collection_name"
   path = "path_to_verity_collection"
   language = "language"
   name = "queryname"
categories = "yes"、"no">

ヒストリ

ColdFusion MX 7:

外部コレクションへのリファレンスが削除されました。
action 属性の map オプションと repair オプションは使用禁止になりました。これらは今後のリリースでは機能せず、エラーが発生する可能性があります。
categories 属性と categorylist アクションが追加されました。
CATEGORIES、SIZE、DOCCOUNT、および LASTMODIFIED が、list アクションによって返される変数のリストに追加されました。
list アクションによって返される MAPPED、ONLINE、および REGISTERED 変数は廃止になりました。

ColdFusion MX:

action 属性の必要条件が変更され、指定が必須になりました。
action 属性の list 値が追加されました。この値がデフォルト値です。
action 属性の値 map の必要条件が変更され、action 属性の値 map を指定する必要がなくなりました。ColdFusion により、コレクションが検出され、必要に応じてコレクションがマッピングされます。
コレクションのネーミング規則が変更され、スペースを含むコレクション名が使用できるようになりました。
Verity オペレーションの動作が変更されました。ColdFusion で、Acrobat PDF ファイルでの Verity オペレーションがサポートされるようになりました。
返される例外が変更されました。このタグでは SEARCHENGINE 例外を返すことができます。

属性

属性	必須/ オプション	デフォルト	説明
action	必須。「使用方法」を参照	list	categorylist: コレクションからカテゴリを取り出し、各カテゴリ内のドキュメント数を示します。構造体の構造体を返します。そこでは、各サブ構造体を表すカテゴリが一連のドキュメントに関連付けられています。カテゴリツリー内のカテゴリの場合、ドキュメントの数はそのツリー内の当該レベル以下のドキュメントの数です。 create: ColdFusion でコレクションを登録します。コレクションが存在する場合は、コレクションのマッピングを作成します。コレクションが存在しない場合は、コレクションを作成します。 delete: コレクションを登録解除してディレクトリから削除します。 list: ColdFusion によって登録されているコレクション群の属性のクエリー結果セットを返します (この結果セットには、`name` 属性値の名前が付けられます)。 map: コレクションのマッピングを作成します。アクションが `create` で、コレクションが既に存在している場合、Coldfusion ではコレクションのマッピングも作成されます。 optimize: 検索のため、コレクションの構造体と内容を最適化します。スペースを元に戻します。コレクションがオフラインになり、検索とインデックス作成ができないようになります。 repair: 使用禁止になりました。何も設定されません。
collection	「使用方法」を参照		コレクション名です。名前にはスペースを含めることができます。
path	「使用方法」を参照		Verity コレクションの絶対パスです。既存のコレクションをマッピングするには、コレクションの完全修飾パスを指定します (コレクション名は含めない)。たとえば、`"C:¥MyCollections¥"` と指定します。
language	「使用方法」を参照	English	English はデフォルトの言語ですが、Englishx という English の拡張ロケールも使用できます。オプションのリストについては、「使用方法」を参照してください。適切な Verity Locales 言語パック (European または Asian) が必要です。
name	「使用方法」を参照		`list` アクションおよび `categorylist` アクションによって返されたクエリー結果の名前です。
categories	「使用方法」を参照	no	コレクション作成のためにのみ使用できます。 yes: このコレクションはカテゴリをサポートします。 no: このコレクションはカテゴリをサポートしません。

使用方法

このタグでは、ColdFusion または Verity アプリケーションによって作成された Verity コレクションの登録および管理を行うことができます。

次の表に、このタグの属性値の依存関係を示します。

各属性の指定要件 (必須、オプション、または不要 (空白))	action 属性の値
各属性の指定要件 (必須、オプション、または不要 (空白))	`list`	`create`	`map`	`optimize`	`repair`	`delete`	`categorylist`
`collection`		必須	必須	必須	必須	必須	必須
`path`		必須	必須
`language`		オプション	オプション
`name`	必須						必須
categories

次の例では、categorylist アクションによって返される構造体を示します。

CATEGORIES
blue	10
green	3
magenta	3
purple	2
CATEGORYTREES
a/	10
a/b	10
a/b/c	10
a/b/c/subdir	3

list アクションは、1 つのコレクションにつき 1 行を含む結果セットを返します。この情報を次に示します。

列	コンテンツ
CATEGORIES	yes: このコレクションではカテゴリのサポートが有効です。 no: このコレクションではカテゴリのサポートが無効です。
CHARSET	コレクションの文字セットです。
CREATED	コレクションが作成された日付と時刻です。
DOCCOUNT	このコレクション内のドキュメントの数です。
EXTERNAL	yes: コレクションは外部です。 no: コレクションは外部ではありません。 Not Found: コレクションは登録されていますが、定義されたパスで取得できません。
LANGUAGE	コレクションのロケール設定です。この情報は K2 サーバーコレクションには使用できません。
LASTMODIFIED	コレクションが最終変更された日付と時刻です。
MAPPED	廃止
NAME	コレクションの名前です。
ONLINE	廃止
PATH	コレクションの絶対パスです。
REGISTERED	廃止
SIZE	コレクションのサイズです。単位はキロバイトです。

ColdFusion MX Administrator の [Verity]-[コレクション] ページには、list 属性を使用したときに返される情報が表示されます。

list アクションの実行時に Verity サーバーが起動していない場合、タグはエラーを返します。

コレクションが存在するかどうか判断するには、次のようなコードを使用して、クエリーオブクエリーを行います。

<cfcollection action="list" name="myCollections" > 
<cfquery name="qoq" dbtype="query">
select * from myCollections
where myCollections.name = 'myCollectionName'
</cfquery> 
<cfif qoq.recordcount GT 0>
   <!--- コレクションが存在します。 --->
   <cfdump var = #qoq#>
</cfif>

Verity サーバーで登録されているすべてのコレクションの値と共に結果セットを取得するには、次のようなコードを使用します。

<cfcollection action="list" name="myCollections">
<cfoutput query="myCollections">
   #name#<br>
</cfoutput>

コレクションに内容を追加するには、cfindex を使用します。コレクションを検索するには、cfsearch を使用します。

このタグの language 属性は次のオプションをサポートします。

Asian 言語パック
Japanese	Korean	Chinese	Traditional Chinese
Multilanguage 言語パック
Unicode
Western European 言語パック
Bokmal	Finnish	Italian	Spanish
Danish	French	Nynorsk	Swedish
Dutch	German	Portuguese
Eastern European/Middle Eastern 言語パック
Arabic	Greek	Polish	Turkish
Bulgarian	Hebrew	Russian
Czech	Hungarian	Russian2

Verity コレクションのデフォルトの保存場所は次のとおりです。

サーバー設定 :
- Windows の場合 : C:¥CFusionMX7¥verity¥collections
- UNIX システムの場合 : /opt/coldfusionmx7/verity/collections
J2EE 設定 : webapp_root/WEB-INF/cfusion/verity/collections

例

<!-------------------------------------------------------------------------
(coll_actn.cfm)
サーバーのプラットフォームを調べ、そのデフォルトの Verity コレクションディレクトリを使用します。
ColdFusion MX をデフォルトのディレクトリにインストールしていない場合、J2EE 設定を
使用する場合、または Web ルートが C:¥CFusionMX7¥wwwroot ではない場合、この例の
パスを変更しなければならないことがあります。たとえば、JRun4 の場合、パスは 
C:¥JRun4¥Verity¥Collections¥ になることがあります。
--------------------------------------------------------------------------->
<cfif Find("Windows", Server.OS.Name)>
   <cfset collPath = "C:¥JRun4¥Verity¥Collections¥">
<cfelse>
   <cfset collpath = "/opt/coldfusionmx7/verity/collections/">
</cfif>

<!--------------------------------------------------------------------------
フォーム入力を処理し、要求された cfcollection オペレーションを実行します。 
--------------------------------------------------------------------------->

<cfif IsDefined("form.CollectionName") AND IsDefined("form.CollectionAction")>
   <cfif form.CollectionName is not "">
      <cfswitch expression="#FORM.CollectionAction#">
        <cfcase value="Create">
          <cfcollection action="CREATE" collection="#FORM.CollectionName#"
               path="#collPath#" categories="yes">
          <h3>コレクションを作成しました。<br>
         CFINDEX を使用してデータを挿入します。</h3>
        </cfcase>
        <cfcase value="Repair">
          <cfcollection action="REPAIR" collection="#FORM.CollectionName#">
          <h3>コレクションを修復しました。</h3>
        </cfcase>
        <cfcase value="Optimize">
          <cfcollection action="OPTIMIZE" collection="#FORM.CollectionName#">
          <h3>コレクションを最適化しました。</h3>
        </cfcase>
        <cfcase value="Delete">
          <cfcollection action="DELETE" collection="#FORM.CollectionName#">
         <h3>コレクションを削除しました。</h3>
        </cfcase>
      </cfswitch>
   <cfelse>
   <h3>コレクションの名前を入力してください。</h3>   
   </cfif>
</cfif>

<!--------------------------------------------------------------------
(coll_form.cfm)
コレクション名とアクションを指定するためのフォーム
   coll_form.cfm
--------------------------------------------------------------------->

<form action="coll_actn.cfm" method="POST" >
<select name="CollectionAction">
   <option value="Create">このコレクションを作成
   <option value="Optimize">このコレクションを最適化
   <option value="Repair">このコレクションを修復
   <option value="Delete">このコレクションを削除
</select>

<p><strong>操作対象のコレクション</strong><br>
デフォルト値を使用するか、コレクション名を入力してください。<br>
<input type="Text" name="CollectionName" value="My_coll"></p>

<input type="Submit" name="" value="コレクションを変更または作成">
</form>

バージョン7

cfcollection

説明

カテゴリ

シンタックス

関連項目

ヒストリ

属性

使用方法

例