toString (Object.toString-Methode)

In diesem Beispiel wird der Rückgabewert für toString() bei einem generischen Objekt angezeigt:

var myObject:Object = new Object();
trace(myObject.toString()); // Ausgabe: [object Object]

Diese Methode kann überschrieben werden, um einen aussagekräftigeren Wert zurückzugeben. Die folgenden Beispiele veranschaulichen, dass diese Methode für die integrierten Klassen Date, Array und Number überschrieben wurde:

// Date.toString() gibt das aktuelle Datum und die aktuelle Uhrzeit zurück.
var myDate:Date = new Date();
trace(myDate.toString()); // Ausgabe: [aktuelles Datum und aktuelle Uhrzeit]

// Array.toString() gibt den Array-Inhalt als kommagetrennten String zurück.
var myArray:Array = new Array("one", "two");
trace(myArray.toString()); // Ausgabe: one,two

// Number.toString() gibt den Zahlenwert als String zurück.
// Da mit trace() nicht angegeben wird, ob es sich bei dem Wert um einen String oder eine Zahl handelt,
// wird auch typeof() verwendet, um die Verwendung von toString() zu testen.
var myNumber:Number = 5;
trace(typeof (myNumber)); // Ausgabe: number
trace(myNumber.toString()); // Ausgabe: 5
trace(typeof (myNumber.toString())); // Ausgabe: string

Das folgende Beispiel veranschaulicht, wie Sie toString() in einer benutzerdefinierten Klasse überschreiben können. Erstellen Sie zunächst eine Textdatei mit dem Namen Vehicle.as, die nur die Klassendefinition Vehicle enthält, und speichern Sie sie im Ordner Classes innerhalb des Ordners Configuration.

// Inhalt von "Vehicle.as"
class Vehicle {
    var numDoors:Number;
    var color:String;
    function Vehicle(param_numDoors:Number, param_color:String) {
    this.numDoors = param_numDoors;
    this.color = param_color;
    }
    function toString():String {
    var doors:String = "door";
    if (this.numDoors > 1) {
        doors += "s";
    }
    return ("A vehicle that is " + this.color + " and has " + this.numDoors + " " + doors);
    }
}

// Programmcode zum Einfügen in die FLA-Datei
var myVehicle:Vehicle = new Vehicle(2, "red");
trace(myVehicle.toString());
// Ausgabe: A vehicle that is red and has 2 doors

// zum Vergleich folgt ein Aufruf von valueOf()
// Es gibt keinen Grundwert von "myVehicle", deshalb wird das Objekt zurückgegeben.
// Die Ausgabe entspricht der von toString().
trace(myVehicle.valueOf());
// Ausgabe: A vehicle that is red and has 2 doors

toString (Object.toString-Methode)

Rückgabewerte

Beispiel