Opérateur d'accès au tableau []

myArray = [ a0, a1,...aN ]
myArray[ i ] = value
myObject [ propertyName ]

Initialise un nouveau tableau ou tableau multidimensionnel avec les éléments spécifiés (a0, etc.) ou accède aux éléments dans un tableau. L'opérateur d'accès au tableau permet de définir et extraire de façon dynamique une occurrence, une variable et des noms d'objet. Il permet également d'accéder aux propriétés d'objet.

Utilisation 1 : Un tableau est un objet dont les propriétés sont appelées des éléments, qui sont tous identifiés par des nombres constituant un index. Lorsque vous créez un tableau, vous entourez les éléments avec l'opérateur d'accès au tableau ([]) ou crochets). Un tableau peut regrouper différents types d'éléments. Par exemple, le tableau suivant, appelé employee, comporte trois éléments ; le premier est un nombre et les deux suivants sont des chaînes (entre guillemets) :

var employee:Array = [15, "Barbara", "Jay"];

Vous pouvez incorporer des crochets pour représenter les tableaux multi-dimensionnels. Vous pouvez incorporer les tableaux jusqu'à 256 niveaux. Le code suivant crée un tableau appelé ticTacToe comportant trois éléments correspondant tous à un tableau de trois éléments :

var ticTacToe:Array = [[1, 2, 3], [4, 5, 6], [7, 8, 9]]; 
// Sélectionner Debug > List Variables en mode de test 
// pour afficher la liste des éléments du tableau.

Utilisation 2 : Mettez l'index de chaque élément entre crochets ([]) pour y accéder directement. Vous pouvez ajouter un nouvel élément à un tableau ou bien modifier ou extraire la valeur d'un élément existant. Le premier index d'un tableau a toujours la valeur 0, comme indiqué dans l'exemple suivant :

var my_array:Array = new Array(); 
my_array[0] = 15; 
my_array[1] = "Hello"; 
my_array[2] = true;

Vous pouvez utiliser des crochets ([]) pour ajouter un quatrième élément, comme indiqué dans l'exemple suivant :

my_array[3] = "George";

Vous pouvez utiliser les crochets ([]) pour accéder à un élément dans un tableau multidimensionnel. La première paire de crochets identifie l'élément dans le tableau d'origine, tandis que la deuxième identifie l'élément dans le tableau incorporé. Les lignes de code suivantes transmettent le chiffre 6 au panneau Sortie.

var ticTacToe:Array = [[1, 2, 3], [4, 5, 6], [7, 8, 9]]; 
trace(ticTacToe[1][2]);// Renvoie : 6

Utilisation 3 : Vous pouvez utiliser l'opérateur d'accès au tableau ([]) à la place de la fonction eval() pour définir et extraire de façon dynamique les valeurs de nom de clip ou toute propriété d'un objet. La ligne de code suivante transmet le chiffre 6 au panneau Sortie.

name["mc" + i] = "left_corner";

Opérandes

a0, a1,...aN : Object - a0,a1,...aN Eléments d'un tableau ; tout type natif ou occurrence d'objet, ce qui inclut les tableaux incorporés.

propertyName : String - propertyName - Chaîne qui nomme une propriété de l'objet.

Valeur renvoyée

Utilisation 2 : Une valeur du tableau ; soit un type natif, soit une occurrence d'objet (ce qui inclut une occurrence de tableau).

Utilisation 3 : Une propriété de l'objet ; soit un type natif, soit une occurrence d'objet (ce qui inclut l'occurrence de tableau).

Exemple

L'exemple suivant illustre deux façons de créer un objet Array vide ; la première ligne utilise des crochets ([]) :

var my_array:Array = []; 
var my_array:Array = new Array();

L'exemple suivant crée un tableau intitulé employee_array et utilise l'instruction trace() pour envoyer les éléments vers le panneau Sortie. À la quatrième ligne, un élément du tableau est modifié, et la cinquième ligne envoie le tableau qui vient d'être modifié vers le panneau Sortie :

var employee_array = ["Barbara", "George", "Mary"]; 
trace(employee_array); // Renvoie : Barbara,George,Mary 
employee_array[2] = "Sam"; 
trace(employee_array); // Renvoie : Barbara,George,Sam

Dans l'exemple suivant, l'expression placée entre crochets ("piece" + i ) est évaluée et le résultat obtenu est utilisé en tant que nom de la variable à récupérer dans le clip my_mc. Dans cet exemple, la variable i doit se trouver sur le même scénario que le bouton. Si la variable i est égale à 5, par exemple, la valeur de la variable piece5 dans le clip my_mc s'affiche dans le panneau Sortie :

myBtn_btn.onRelease = function(){ 
 x = my_mc["piece"+i]; 
 trace(x); 
};

Dans l'exemple suivant, l'expression placée entre crochets est évaluée et le résultat obtenu est utilisé en tant que nom de la variable à récupérer dans le clip name_mc :

name_mc["A" + i];

Si vous maîtrisez la syntaxe à barre oblique ActionScript de Flash 4, vous pouvez utiliser la fonction eval() pour obtenir le même résultat :

eval("name_mc.A" & i);

Vous pouvez utiliser le code ActionScript suivant pour passer en boucle sur tous les objets du domaine _root ce qui est particulièrement utile en vue du débogage :

for (i in _root) { 
 trace(i+": "+_root[i]); 
}

Vous pouvez également utiliser l'opérateur d'accès au tableau ([]) dans la partie gauche d'une instruction d'affectation pour définir de façon dynamique les noms d'objet, de variable et d'occurrence :

employee_array[2] = "Sam";

Opérateur d'accès au tableau []

Opérandes

Valeur renvoyée

Exemple

Voir aussi