toString (méthode Object.toString)

Cet exemple affiche la valeur renvoyée pour toString() sur un objet générique :

var myObject:Object = new Object();
trace(myObject.toString()); // Renvoie : [object Object]

Cette méthode peut être remplacée pour renvoyer une valeur plus significative. Les exemples suivants indiquent que cette méthode a été remplacée pour les classes intégrées Date, Array et Number :

// Date.toString() renvoie la date et l'heure actuelle
var myDate:Date = new Date();
trace(myDate.toString()); // Renvoie : [date et heure actuelle]

// Array.toString() renvoie le contenu du tableau sous forme de chaîne 
// séparée par des virgules
var myArray:Array = new Array("one", "two");
trace(myArray.toString()); // Renvoie : one,two

// Number.toString() renvoie la valeur numérique sous forme de chaîne
// Dans la mesure où trace() n'indique pas si la valeur est une chaîne ou un 
// nombre, nous allons également utiliser typeof() pour tester le 
// fonctionnement de toString().
var myNumber:Number = 5;
trace(typeof (myNumber)); // Renvoie : nombre
trace(myNumber.toString()); // Renvoie : 5
trace(typeof (myNumber.toString())); // Renvoie : une chaîne

L'exemple suivant indique comment remplacer toString() dans une classe personnalisée. Créez tout d'abord un fichier texte appelé Vehicle.as contenant la définition de la classe Vehicle et placez-le dans le dossier Classes figurant dans le dossier Configuration.

// Contenu de Vehicle.as
class Vehicle {
    var numDoors:Number;
    var color:String;
    function Vehicle(param_numDoors:Number, param_color:String) {
    this.numDoors = param_numDoors;
    this.color = param_color;
    } 
    function toString():String {
    var doors:String = "door";
    if (this.numDoors > 1) {
        doors += "s";
    } 
    return ("A vehicle that is " + this.color + " and has " + this.numDoors + " " + doors);
    } 
}

// Code à placer dans un fichier FLA
var myVehicle:Vehicle = new Vehicle(2, "red");
trace(myVehicle.toString());
// Renvoie : A vehicle that is red and has 2 doors

// Pour des raisons de comparaison, ceci est un appel à valueOf()
// Il n'existe pas de valeur primitive de myVehicle, par conséquent 
// l'objet est renvoyé 
// en donnant la même sortie que toString().
trace(myVehicle.valueOf());
// Renvoie : A vehicle that is red and has 2 doors

toString (méthode Object.toString)

Valeur renvoyée

Exemple