autoSize (propriété TextField.autoSize)

Commande le dimensionnement et l'alignement automatiques des champs texte. Les valeurs acceptables pour autoSize sont "none" (par défaut), "left", "right" et "center". Lorsque vous définissez la propriété autoSize , true est synonyme de "left" et false est synonyme de "none".

Les valeurs de autoSize et TextField.wordWrap déterminent si un champ texte est agrandi ou réduit vers la gauche, la droite ou le bas. La valeur par défaut pour chacune de ces propriétés est false.

Si autoSize est défini sur "none" (valeur par défaut) ou false, il n'y a aucun redimensionnement.

Si autoSize est défini sur "left" ou true, le texte est alors traité comme du texte cadré à gauche, ce qui signifie que le côté gauche du texte reste fixe et tout redimensionnement d'un champ texte sur une seule ligne se fera à droite. Si le texte contient un saut de ligne (par exemple "\n" or "\r") le bas est alors également redimensionné pour s'adapter à la ligne suivante du texte. Si wordWrap est également défini sur true, seul le bas du champ texte est redimensionné et le côté droit reste fixe.

Si autoSize est défini sur "right", le texte est alors traité comme du texte cadré à droite, ce qui signifie que le côté droit du texte reste fixe et tout redimensionnement d'un champ texte sur une seule ligne se fera à gauche. Si le texte contient un saut de ligne (par exemple "\n" or "\r") le bas est alors également redimensionné pour s'adapter à la ligne suivante du texte. Si wordWrap est également défini sur true, seul le bas du champ texte est redimensionné et le côté gauche reste fixe.

Si autoSize est défini sur "center", le texte est traité comme du texte centré, ce qui signifie que tout redimensionnement d'un champ texte sur une seule ligne est uniformément réparti sur les côtés droit et gauche. Si le texte contient un saut de ligne (par exemple "\n" or "\r") le bas est alors également redimensionné pour s'adapter à la ligne suivante du texte. Si wordWrap est également défini sur true, seul le bas du champ texte est redimensionné et les côtés gauche et droit restent fixes.

Exemple

Utilisez le code suivant et entrez différentes valeurs pour autoSize de façon à voir comment le champ se redimensionne en fonction de ces valeurs. Un clic de souris pendant la lecture du fichier SWF remplace la chaîne "short text" de chaque champ par un texte plus long et appliquant différents paramètres pour autoSize.

this.createTextField("left_txt", 997, 10, 10, 70, 30);
this.createTextField("center_txt", 998, 10, 50, 70, 30);
this.createTextField("right_txt", 999, 10, 100, 70, 30);
this.createTextField("true_txt", 1000, 10, 150, 70, 30);
this.createTextField("false_txt", 1001, 10, 200, 70, 30);

left_txt.text = "short text";
left_txt.border = true;

center_txt.text = "short text";
center_txt.border = true;

right_txt.text = "short text";
right_txt.border = true;

true_txt.text = "short text";
true_txt.border = true;

false_txt.text = "short text";
false_txt.border = true;

// Création d'un objet écouteur, Mouse, permettant de détecter les clics de la souris
var myMouseListener:Object = new Object();
// Définition d'une fonction à exécuter lorsqu'un utilisateur clique avec la souris
myMouseListener.onMouseDown = function() {
    left_txt.autoSize = "left";
    left_txt.text = "This is much longer text";
    center_txt.autoSize = "center";
    center_txt.text = "This is much longer text";
    right_txt.autoSize = "right";
    right_txt.text = "This is much longer text";
    true_txt.autoSize = true;
    true_txt.text = "This is much longer text"; 
    false_txt.autoSize = false;
    false_txt.text = "This is much longer text";
};
// Association de l'objet écouteur à l'objet Mouse
Mouse.addListener(myMouseListener);