styleSheet (propriété TextField.styleSheet)

Associe une feuille de style au champ texte. Pour plus d'informations sur la création des feuilles de style, consultez l'entrée relative à la classe TextField.StyleSheet.

La feuille de style associée à un champ texte peut être modifiée à tout moment. Si la feuille de style en cours d'utilisation est modifiée, le champ texte est redessiné avec la nouvelle feuille de style. La feuille de style peut être définie sur null ou undefined pour la supprimer. Si la feuille de style en cours d'utilisation est supprimée, le champ texte est redessiné sans feuille de style. La mise en forme effectuée par une feuille de style n'est pas conservée si cette dernière est supprimée.

Exemple

L'exemple suivant crée un champ texte lors de l'exécution, appelé news_txt. Trois boutons placés sur la Scène, css1_btn, css2_btn et clearCss_btn, permettent de changer la feuille de style qui s'applique à news_txt, ou à supprimer la feuille de style du champ texte. Ajoutez le code ActionScript suivant à votre fichier ActionScript ou FLA :

this.createTextField("news_txt", this.getNextHighestDepth(), 0, 0, 300, 200);
news_txt.wordWrap = true;
news_txt.multiline = true;
news_txt.html = true;
var newsText:String = "<p class='headline'>Description</p> Method; "
    + "starts loading the CSS file into styleSheet. The load operation is asynchronous; "
    + "use the <span class='bold'>TextField.StyleSheet.onLoad</span> "
    + "callback handler to determine when the file has finished loading. "
    + "<span class='important'>The CSS file must reside in exactly the same "
    + "domain as the SWF file that is loading it.</span> For more information about "
    + "restrictions on loading data across domains, see Flash Player security features.";

news_txt.htmlText = newsText;

css1_btn.onRelease = function() {
    var styleObj:TextField.StyleSheet = new TextField.StyleSheet();
    styleObj.onLoad = function(success:Boolean) {
    if (success) {
        news_txt.styleSheet = styleObj;
        news_txt.htmlText = newsText;
    } 
    };
    styleObj.load("styles.css");
};

css2_btn.onRelease = function() {
    var styleObj:TextField.StyleSheet = new TextField.StyleSheet();
    styleObj.onLoad = function(success:Boolean) {
    if (success) {
        news_txt.styleSheet = styleObj;
        news_txt.htmlText = newsText;
    } 
    };
    styleObj.load("styles2.css");
};

clearCss_btn.onRelease = function() {
    news_txt.styleSheet = undefined;
    news_txt.htmlText = newsText;
};

Les styles suivants sont appliqués au champ texte. Enregistrez les deux fichiers CSS dans le même répertoire que le fichier FLA ou ActionScript que vous avez créé auparavant :

// Dans styles.css 
.important {
    color: #FF0000;
}
.bold {
    font-weight: bold;
}
.headline {
    color: #000000;
    font-family: Arial,Helvetica,sans-serif;
    font-size: 18px;
    font-weight: bold;
    display: block;
}

// Dans styles2.css 
.important {
    color: #FF00FF;
}
.bold {
    font-weight: bold;
}
.headline {
    color: #00FF00;
    font-family: Arial,Helvetica,sans-serif;
    font-size: 18px;
    font-weight: bold;
    display: block;
}