Flash Lite 2 
Flash Lite 2.x ActionScript リファレンスガイド > ActionScript クラス > LoadVars > getBytesLoaded (LoadVars.getBytesLoaded メソッド)

getBytesLoaded (LoadVars.getBytesLoaded メソッド)

public getBytesLoaded() : Number

LoadVars.load() または LoadVars.sendAndLoad() によってダウンロードされたバイト数を返します。ロード処理が実行中ではない場合、またはまだ始まっていない場合は、undefined を返します。

使用できるバージョン : ActionScript 1.0、Flash Lite 2.0

戻り値

Number - 整数。

例

次の例では、ProgressBar インスタンスおよび LoadVars オブジェクトを使用して、テキストファイルをダウンロードします。ファイルをテストすると、ファイルのロードの成否と SWF ファイルにロードされたデータ量が [出力] パネルに表示されます。LoadVars.load() コマンドの URL パラメータは、HTTP を使用して有効なテキストファイルを指定するように値を置き換える必要があります。この例を使用してハードディスク上にあるローカルファイルをロードしようとしても、ムービープレビューモードの Flash Player ではローカルファイル全体がロードされるので、正常に機能しません。このコードの動作を確認するには、ProgressBar インスタンス loadvars_pb をステージに追加します。次に、タイムラインのフレーム 1 に次の ActionScript を追加します。 

var loadvars_pb: mx.controls.ProgressBar;
var my_lv: LoadVars = new LoadVars();
loadvars_pb.mode = "manual";
this.createEmptyMovieClip("timer_mc", 999);
timer_mc.onEnterFrame = function() {
    var lvBytesLoaded: Number = my_lv.getBytesLoaded();
    var lvBytesTotal: Number = my_lv.getBytesTotal();
    if (lvBytesTotal != undefined) {
    trace("Loaded "+lvBytesLoaded+" of "+lvBytesTotal+" bytes.");
    loadvars_pb.setProgress(lvBytesLoaded, lvBytesTotal);
    }
};
my_lv.onLoad = function(success: Boolean) {
    loadvars_pb.setProgress(my_lv.getBytesLoaded(), my_lv.getBytesTotal());
    delete timer_mc.onEnterFrame;
    if (success) {
    trace("LoadVars loaded successfully.");
    } else {
    trace("An error occurred while loading variables.");
    }
};
my_lv.load("[place a valid URL pointing to a text file here]");

関連項目

load (LoadVars.load メソッド), sendAndLoad (LoadVars.sendAndLoad メソッド)