パッケージトップレベル
public final dynamic class Date
継承Date Inheritance Object

Date クラスは日時のデータを表します。Date クラスの 1 つのインスタンスは特定の一時点を表します。この特定の一時点について、月、日、時、秒などのプロパティを照会および変更できます。Date クラスを使用すると、世界時 (グリニッジ標準時。現在の呼称は世界標準時または UTC) またはローカル時間を基準にした日付と時刻の値を取得できます。ローカル時間は、Flash Player を実行しているオペレーティングシステムに設定されているローカルタイムゾーンによって決定されます。Date クラスのメソッドは静的ではありません。メソッドを呼び出すときに指定した個々の Date オブジェクトにのみ適用されます。Date.UTC() メソッドと Date.parse() メソッドは例外であり、これらは静的なメソッドです。

Date クラスによる夏時間の処理方法は、オペレーティングシステムおよび Flash Player のバージョンに応じて異なります。Flash Player 6 以降では、夏時間は各オペレーティングシステムで次のように処理されます。

Flash Player 5 によるオペレーティングシステム別の夏時間の対処方法は次のとおりです。

Date クラスを使用するには、new 演算子を使用して Date インスタンスを作成します。

ActionScript 3.0 は新しいアクセサプロパティをいくつか追加しています。これらのアクセサプロパティは、Date インスタンスにアクセスしたり、Date インスタンスを変更する多くの Date クラスメソッドの代わりに使用できます。また、ActionScript 3.0 には、ECMA-262 Edition 3 に準拠するために組み込まれている、toString() メソッドの新しい変形メソッド (Date.toLocaleString()、Date.toTimeString()、Date.toLocaleTimeString()、Date.toDateString()、および Date.toLocaleDateString()) も含まれます。

相対時間または経過時間を計算するには、flash.utils パッケージに含まれる getTimer() メソッドを参照してください。

例の表示

関連項目

flash.utils.getTimer()
日付と時刻の操作

パブリックプロパティ
 プロパティ定義
 Inheritedconstructor : Object
特定のオブジェクトインスタンスのクラスオブジェクトまたはコンストラクタ関数への参照です。
Object
  date : Number
Date オブジェクトで指定されたローカル時間による日付 (1 ～ 31 の整数) です。
Date
  dateUTC : Number
Date オブジェクトの世界時 (UTC) による日付 (1 ～ 31 の整数) です。
Date
  day : Number
[read-only] この Date で指定されたローカル時間による曜日 (日曜日は 0、月曜日は 1 など) です。
Date
  dayUTC : Number
[read-only] この Date の世界時 (UTC) による曜日 (日曜日は 0、月曜日は 1 など) です。
Date
  fullYear : Number
Date オブジェクトのローカル時間による年 (2000 などの 4 桁の数字) です。
Date
  fullYearUTC : Number
Date オブジェクトの世界時 (UTC) による 4 桁の年です。
Date
  hours : Number
Date オブジェクトのローカル時間による時 (0 ～ 23 の整数) 部分です。
Date
  hoursUTC : Number
Date オブジェクトの世界時 (UTC) による時 (0 ～ 23 の整数) です。
Date
  milliseconds : Number
Date オブジェクトのローカル時間によるミリ秒 (0 ～ 999 の整数) 部分です。
Date
  millisecondsUTC : Number
Date オブジェクトの世界時 (UTC) によるミリ秒 (0 ～ 999 の整数) 部分です。
Date
  minutes : Number
Date オブジェクトのローカル時間による分 (0 ～ 59 の整数) 部分です。
Date
  minutesUTC : Number
Date オブジェクトの世界時 (UTC) による分 (0 ～ 59 の整数) 部分です。
Date
  month : Number
Date オブジェクトのローカル時間による月 (1 月は 0、2 月は 1 など) です。
Date
  monthUTC : Number
Date オブジェクトの世界時 (UTC) による月 (0 [1 月] ～ 11 [12 月]) 部分です。
Date
 Inheritedprototype : Object
[static] クラスまたは関数オブジェクトのプロトタイプオブジェクトへの参照です。
Object
  seconds : Number
Date オブジェクトのローカル時間による秒 (0 ～ 59 の整数) 部分です。
Date
  secondsUTC : Number
Date オブジェクトの世界時 (UTC) による秒 (0 ～ 59 の整数) 部分です。
Date
  time : Number
Date オブジェクトの 1970 年 1 月 1 日 0 時 (世界時) からのミリ秒数です。
Date
  timezoneOffset : Number
[read-only] コンピュータのローカル時間と世界時 (UTC) の差 (分単位) です。
Date
パブリックメソッド
 メソッド定義
  Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)
指定された日時を保持する新しい Date オブジェクトを作成します。
Date
  getDate():Number
Date オブジェクトで指定された日付 (1 ～ 31 の整数) をローカル時間で返します。
Date
  getDay():Number
この Date で指定された曜日 (日曜日は 0、月曜日は 1 など) をローカル時間で返します。
Date
  getFullYear():Number
Date オブジェクトの年 (2000 などの 4 桁の数字) をローカル時間で返します。
Date
  getHours():Number
Date オブジェクトの時 (0 ～ 23 の整数) 部分をローカル時間で返します。
Date
  getMilliseconds():Number
Date オブジェクトのミリ秒 (0 ～ 999 の整数) 部分をローカル時間で返します。
Date
  getMinutes():Number
Date オブジェクトの分 (0 ～ 59 の整数) 部分をローカル時間で返します。
Date
  getMonth():Number
この Date の月 (1 月は 0、2 月は 1 など) 部分をローカル時間で返します。
Date
  getSeconds():Number
Date オブジェクトの秒 (0 ～ 59 の整数) 部分をローカル時間で返します。
Date
  getTime():Number
Date オブジェクトの 1970 年 1 月 1 日 0 時 (世界時) からのミリ秒数を返します。
Date
  getTimezoneOffset():Number
コンピュータのローカル時間と世界時 (UTC) の差 (分単位) を返します。
Date
  getUTCDate():Number
Date オブジェクトの日付 (1 ～ 31 の整数) を世界時 (UTC) で返します。
Date
  getUTCDay():Number
この Date の曜日 (日曜日は 0、月曜日は 1 など) を世界時 (UTC) で返します。
Date
  getUTCFullYear():Number
Date オブジェクトの 4 桁の年を世界時 (UTC) で返します。
Date
  getUTCHours():Number
Date オブジェクトの時 (0 ～ 23 の整数) を世界時 (UTC) で返します。
Date
  getUTCMilliseconds():Number
Date オブジェクトのミリ秒 (0 ～ 999 の整数) 部分を世界時 (UTC) で返します。
Date
  getUTCMinutes():Number
Date オブジェクトの分 (0 ～ 59 の整数) 部分を世界時 (UTC) で返します。
Date
  getUTCMonth():Number
Date オブジェクトの月 (0 [1 月] ～ 11 [12 月]) 部分を世界時 (UTC) で返します。
Date
  getUTCSeconds():Number
Date オブジェクトの秒 (0 ～ 59 の整数) 部分を世界時 (UTC) で返します。
Date
 InheritedhasOwnProperty(name:String):Boolean
オブジェクトに指定されたプロパティが定義されているかどうかを示します。
Object
 InheritedisPrototypeOf(theClass:Object):Boolean
Object クラスのインスタンスが、パラメータとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。
Object
  parse(date:String):Number
[static] 日付を表すストリングを、1970 年 1 月 1 日 (UTC) から経過したミリ秒数に相当する数値に変換します。
Date
 InheritedpropertyIsEnumerable(name:String):Boolean
指定されたプロパティが存在し、列挙可能かどうかを示します。
Object
  setDate(day:Number):Number
月内の日付をローカル時間で設定し、新しい時刻をミリ秒で返します。
Date
  setFullYear(year:Number, month:Number, day:Number):Number
年をローカル時間で設定し、新しい時刻をミリ秒で返します。
Date
  setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
時をローカル時間で設定し、新しい時刻をミリ秒で返します。
Date
  setMilliseconds(millisecond:Number):Number
ミリ秒をローカル時間で設定し、新しい時刻をミリ秒で返します。
Date
  setMinutes(minute:Number, second:Number, millisecond:Number):Number
分をローカル時間で設定し、新しい時刻をミリ秒で返します。
Date
  setMonth(month:Number, day:Number):Number
月と、オプションで日付をローカル時間で設定し、新しい時刻をミリ秒で返します。
Date
 InheritedsetPropertyIsEnumerable(name:String, isEnum:Boolean = true):void
ループ処理に対するダイナミックプロパティの可用性を設定します。
Object
  setSeconds(second:Number, millisecond:Number):Number
秒をローカル時間で設定し、新しい時刻をミリ秒で返します。
Date
  setTime(millisecond:Number):Number
日付を 1970 年 1 月 1 日 0 時からのミリ秒数で設定し、新しい時刻をミリ秒で返します。
Date
  setUTCDate(day:Number):Number
月内の日付を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。
Date
  setUTCFullYear(year:Number, month:Number, day:Number):Number
年を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。
Date
  setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
時を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。
Date
  setUTCMilliseconds(millisecond:Number):Number
ミリ秒を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。
Date
  setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number
分を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。
Date
  setUTCMonth(month:Number, day:Number):Number
月、およびオプションで日を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。
Date
  setUTCSeconds(second:Number, millisecond:Number):Number
秒、およびオプションでミリ秒を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。
Date
  toDateString():String
曜日と日付のみのストリング表現を返します。時刻またはタイムゾーンは含まれません。
Date
  toLocaleDateString():String
曜日と日付のみのストリング表現を返します。時刻またはタイムゾーンは含まれません。
Date
  toLocaleString():String
曜日、日付、時刻のストリング表現を、指定されたローカル時間で返します。
Date
  toLocaleTimeString():String
時刻のみのストリング表現を返します。曜日、日付、年、またはタイムゾーンは含まれません。
Date
  toString():String
曜日、日付、時刻、およびタイムゾーンのストリング表現を返します。
Date
  toTimeString():String
時刻とタイムゾーンのみのストリング表現を返します。曜日と日付は含まれません。
Date
  toUTCString():String
曜日、日付、および時刻のストリング表現を世界時 (UTC) で返します。
Date
  UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number
[static] 1970 年 1 月 1 日 0 時 (世界時) からパラメータで指定された時刻までのミリ秒数を返します。
Date
  valueOf():Number
Date オブジェクトの 1970 年 1 月 1 日 0 時 (世界時) からのミリ秒数を返します。
Date
プロパティの詳細
dateプロパティ
date:Number  [read-write]

Date オブジェクトで指定されたローカル時間による日付 (1 ～ 31 の整数) です。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

実装
    AS3 function get date():Number
    AS3 function set date(value:Number):void

関連項目

getDate()
setDate()
カレンダー日付と時刻の管理
dateUTCプロパティ 
dateUTC:Number  [read-write]

Date オブジェクトの世界時 (UTC) による日付 (1 ～ 31 の整数) です。

実装
    AS3 function get dateUTC():Number
    AS3 function set dateUTC(value:Number):void

関連項目

getUTCDate()
setUTCDate()
dayプロパティ 
day:Number  [read-only]

この Date で指定されたローカル時間による曜日 (日曜日は 0、月曜日は 1 など) です。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

実装
    AS3 function get day():Number

関連項目

getDay()
カレンダー日付と時刻の管理
dayUTCプロパティ 
dayUTC:Number  [read-only]

この Date の世界時 (UTC) による曜日 (日曜日は 0、月曜日は 1 など) です。

実装
    AS3 function get dayUTC():Number

関連項目

getUTCDay()
fullYearプロパティ 
fullYear:Number  [read-write]

Date オブジェクトのローカル時間による年 (2000 などの 4 桁の数字) です。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

実装
    AS3 function get fullYear():Number
    AS3 function set fullYear(value:Number):void

関連項目

getFullYear()
setFullYear()
カレンダー日付と時刻の管理
fullYearUTCプロパティ 
fullYearUTC:Number  [read-write]

Date オブジェクトの世界時 (UTC) による 4 桁の年です。

実装
    AS3 function get fullYearUTC():Number
    AS3 function set fullYearUTC(value:Number):void

関連項目

getUTCFullYear()
setUTCFullYear()
hoursプロパティ 
hours:Number  [read-write]

Date オブジェクトのローカル時間による時 (0 ～ 23 の整数) 部分です。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

実装
    AS3 function get hours():Number
    AS3 function set hours(value:Number):void

関連項目

getHours()
setHours()
カレンダー日付と時刻の管理
hoursUTCプロパティ 
hoursUTC:Number  [read-write]

Date オブジェクトの世界時 (UTC) による時 (0 ～ 23 の整数) です。

実装
    AS3 function get hoursUTC():Number
    AS3 function set hoursUTC(value:Number):void

関連項目

getUTCHours()
setUTCHours()
millisecondsプロパティ 
milliseconds:Number  [read-write]

Date オブジェクトのローカル時間によるミリ秒 (0 ～ 999 の整数) 部分です。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

実装
    AS3 function get milliseconds():Number
    AS3 function set milliseconds(value:Number):void

関連項目

getMilliseconds()
setMilliseconds()
カレンダー日付と時刻の管理
millisecondsUTCプロパティ 
millisecondsUTC:Number  [read-write]

Date オブジェクトの世界時 (UTC) によるミリ秒 (0 ～ 999 の整数) 部分です。

実装
    AS3 function get millisecondsUTC():Number
    AS3 function set millisecondsUTC(value:Number):void

関連項目

getUTCMilliseconds()
setUTCMilliseconds()
minutesプロパティ 
minutes:Number  [read-write]

Date オブジェクトのローカル時間による分 (0 ～ 59 の整数) 部分です。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

実装
    AS3 function get minutes():Number
    AS3 function set minutes(value:Number):void

関連項目

getMinutes()
setMinutes()
カレンダー日付と時刻の管理
minutesUTCプロパティ 
minutesUTC:Number  [read-write]

Date オブジェクトの世界時 (UTC) による分 (0 ～ 59 の整数) 部分です。

実装
    AS3 function get minutesUTC():Number
    AS3 function set minutesUTC(value:Number):void

関連項目

getUTCMinutes()
setUTCMinutes()
monthプロパティ 
month:Number  [read-write]

Date オブジェクトのローカル時間による月 (1 月は 0、2 月は 1 など) です。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

実装
    AS3 function get month():Number
    AS3 function set month(value:Number):void

関連項目

getMonth()
setMonth()
カレンダー日付と時刻の管理
monthUTCプロパティ 
monthUTC:Number  [read-write]

Date オブジェクトの世界時 (UTC) による月 (0 [1 月] ～ 11 [12 月]) 部分です。

実装
    AS3 function get monthUTC():Number
    AS3 function set monthUTC(value:Number):void

関連項目

getUTCMonth()
setUTCMonth()
secondsプロパティ 
seconds:Number  [read-write]

Date オブジェクトのローカル時間による秒 (0 ～ 59 の整数) 部分です。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

実装
    AS3 function get seconds():Number
    AS3 function set seconds(value:Number):void

関連項目

getSeconds()
setSeconds()
カレンダー日付と時刻の管理
secondsUTCプロパティ 
secondsUTC:Number  [read-write]

Date オブジェクトの世界時 (UTC) による秒 (0 ～ 59 の整数) 部分です。

実装
    AS3 function get secondsUTC():Number
    AS3 function set secondsUTC(value:Number):void

関連項目

getUTCSeconds()
setUTCSeconds()
timeプロパティ 
time:Number  [read-write]

Date オブジェクトの 1970 年 1 月 1 日 0 時 (世界時) からのミリ秒数です。このメソッドは、複数の Date オブジェクトを比較する際に特定の時間を表すのに使用します。

実装
    AS3 function get time():Number
    AS3 function set time(value:Number):void

関連項目

getTime()
setTime()
timezoneOffsetプロパティ 
timezoneOffset:Number  [read-only]

コンピュータのローカル時間と世界時 (UTC) の差 (分単位) です。

実装
    AS3 function get timezoneOffset():Number

関連項目

getTimezoneOffset()
コンストラクタの詳細
Date()コンストラクタ
public 関数 Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)

指定された日時を保持する新しい Date オブジェクトを作成します。

Date() コンストラクタは、日付と、ミリ秒までの時刻を指定するために、最大 7 つまでパラメータ (year、month、...、millisecond) を取ります。新しく作成された Date オブジェクトに含まれる日付は、渡された引数の数とデータ型により異なります。

Date クラスのコンストラクタにストリングを渡す場合、日付にはさまざまな形式を使用できますが、少なくとも月、日、年が含まれている必要があります。たとえば、Feb 1 2005 は有効ですが、Feb 2005 は無効です。次に、有効な形式をいくつか示します。

パラメータ
yearOrTimevalue:Object — 他のパラメータが指定されている場合、この数値は年 (1965 年など) を表します。それ以外の場合は時間値を表します。数値が年を表す場合、0 ～ 99 の値は 1900 ～ 1999 を表します。それ以外の場合は年を 4 桁で指定する必要があります。数値が時間値を表す (他にパラメータが指定されない) 場合は、1970 年 1 月 1 日 0:00:00 を基準とする経過時間をミリ秒単位で表す値になります。負の値は 1970 年 1 月 1 日 0:00:00 GMT よりも前の時刻を表し、正の値はそれより後の時刻を表します。
 
month:Number — 0 (1 月) ～ 11 (12 月) の整数です。
 
date:Number (default = 1) — 1 ～ 31 の整数です。
 
hour:Number (default = 0) — 0 (0 時) ～ 23 (午後 11 時) の整数です。
 
minute:Number (default = 0) — 0 ～ 59 の整数です。
 
second:Number (default = 0) — 0 ～ 59 の整数です。
 
millisecond:Number (default = 0) — ミリ秒の 0 ～ 999 の整数です。

関連項目

getMonth()
getDate()
getFullYear()
カレンダー日付と時刻の管理
メソッドの詳細
getDate()メソッド
AS3 function getDate():Number

Date オブジェクトで指定された日付 (1 ～ 31 の整数) をローカル時間で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

戻り値
Number — Date オブジェクトが表す日付 (1 ～ 31) です。

関連項目

getMonth()
getFullYear()

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。 次に、getDate() メソッドを呼び出し、日付を取得します。 
package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}

getDay()メソッド 
AS3 function getDay():Number

この Date で指定された曜日 (日曜日は 0、月曜日は 1 など) をローカル時間で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

戻り値
Number — Date オブジェクトが表す曜日の数値 (0 ～ 6) です。

例
次の例では、新しい Array オブジェクト weekDayLabels を作成します。エレメントは [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] です。また、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。 次に、getDay() メソッドを 2 回呼び出します。1 回目は曜日を 6 という数値で表示し、2 回目は weekDayLabels を使用して曜日を表示します。 

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday

getFullYear()メソッド 
AS3 function getFullYear():Number

Date オブジェクトの年 (2000 などの 4 桁の数字) をローカル時間で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

戻り値
Number — Date オブジェクトが表す 4 桁の年です。

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。 次に、getFullYear() メソッドを呼び出し、4 桁の年を取得します。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

getHours()メソッド 
AS3 function getHours():Number

Date オブジェクトの時 (0 ～ 23 の整数) 部分をローカル時間で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

戻り値
Number — Date オブジェクトが表す時 (0 ～ 23) です。

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。 次に、getHours() メソッドと getMinutes() メソッドを呼び出し、 時と分を 24 時間形式で取得します。最後に、ストリング localTime を作成し、 関数 getUSClockTime() を呼び出した結果に割り当てます。この関数は、 getHours() と getMinutes() を再度呼び出します。これにより、時間 03:05 PM が表示されます。 

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}

getMilliseconds()メソッド 
AS3 function getMilliseconds():Number

Date オブジェクトのミリ秒 (0 ～ 999 の整数) 部分をローカル時間で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

戻り値
Number — Date オブジェクトのミリ秒部分です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getMilliseconds() メソッドを呼び出し、 Date オブジェクト now の作成時点の分を取得します。 

var now:Date = new Date();
trace(now.getMilliseconds());

getMinutes()メソッド 
AS3 function getMinutes():Number

Date オブジェクトの分 (0 ～ 59 の整数) 部分をローカル時間で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

戻り値
Number — Date オブジェクトの分部分です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getMinutes() メソッドを呼び出し、 Date オブジェクト now の作成時点の分を取得します。 

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

getMonth()メソッド 
AS3 function getMonth():Number

この Date の月 (1 月は 0、2 月は 1 など) 部分をローカル時間で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

戻り値
Number — Date オブジェクトの月 (0 ～ 11) 部分です。

例
次の例では、新しい Array オブジェクト monthLabels を作成します。エレメントは January ～ December です。また、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getMonth() メソッドを 2 回呼び出します。1 回目は、Date オブジェクト now が作成された月の数値を返し、2 回目は月の名前を返します。 

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

getSeconds()メソッド 
AS3 function getSeconds():Number

Date オブジェクトの秒 (0 ～ 59 の整数) 部分をローカル時間で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

戻り値
Number — Date オブジェクトの秒 (0 ～ 59 の整数) 部分です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getSeconds() メソッドを呼び出し、 Date オブジェクト now の作成時点の分を取得します。 

var now:Date = new Date();
trace(now.getSeconds());

getTime()メソッド 
AS3 function getTime():Number

Date オブジェクトの 1970 年 1 月 1 日 0 時 (世界時) からのミリ秒数を返します。このメソッドは、複数の Date オブジェクトを比較する際に特定の時間を表すのに使用します。

戻り値
Number — Date オブジェクトが表す 1970 年 1 月 1 日からのミリ秒数です。

例
次の例では、新しい Date オブジェクト mlkを作成します。パラメータには、 year (1929)、month (0 = 1 月)、および day (15) を指定します。次に、getTime() メソッドを呼び出し、 1970 年 1 月 1 日午前 0 時からのミリ秒数を取得します。年が 1929 に設定されているため、ミリ秒は負の値で表されます。 

var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、以下で作成する DateMath クラスのメソッドを使用して、元の Date オブジェクト now が作成されてからの時間を追加します。 

var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}
メモ :Date 算術演算を実行するときは getTime を使用することが重要です。これは、 Date 算術演算がうるう年にも動作し続け、次の擬似コードのような一連の if 論理を必要としないためです。 
 function addMonths(num:Number):void {
     currentMonth = currentMonth + num;
     if(currentMonth > 12) {
         currentYear++;
         currentMonth = currentMonth - 12;
      }
  }


getTimezoneOffset()メソッド 
AS3 function getTimezoneOffset():Number

コンピュータのローカル時間と世界時 (UTC) の差 (分単位) を返します。

戻り値
Number — ローカル時間と世界時 (UTC) の差 (分単位) です

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getTimezoneOffset() メソッドを呼び出し、 now が作成された時刻と世界時の差 (分単位) を取得します。さらに、この結果を 60 で除算して、タイムゾーンのオフセットを 時間単位に変換します。 

var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);

getUTCDate()メソッド 
AS3 function getUTCDate():Number

Date オブジェクトの日付 (1 ～ 31 の整数) を世界時 (UTC) で返します。

戻り値
Number — Date オブジェクトが表す UTC の日付 (1 ～ 31) です。

関連項目

getDate()

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。 次に、getUTCDate() メソッドを呼び出し、日付を UTC で取得します。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

getUTCDay()メソッド 
AS3 function getUTCDay():Number

この Date の曜日 (日曜日は 0、月曜日は 1 など) を世界時 (UTC) で返します。

戻り値
Number — Date オブジェクトが表す UTC の曜日 (0 ～ 6) です。

関連項目

getDay()

例
次の例では、新しい Array オブジェクト weekDayLabels を作成します。エレメントは [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] です。また、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。 次に、getUTCDay() メソッドを 2 回呼び出します。1 回目は曜日を 6 という数値で表示し、2 回目は weekDayLabels を使用して曜日を UTC で表示します。 

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday

getUTCFullYear()メソッド 
AS3 function getUTCFullYear():Number

Date オブジェクトの 4 桁の年を世界時 (UTC) で返します。

戻り値
Number — Date オブジェクトが表す UTC の 4 桁の年です。

関連項目

getFullYear()

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。 次に、getUTCFullYear() メソッドを呼び出し、4 桁の年を UTC で取得します。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

getUTCHours()メソッド 
AS3 function getUTCHours():Number

Date オブジェクトの時 (0 ～ 23 の整数) を世界時 (UTC) で返します。

戻り値
Number — Date オブジェクトが表す UTC の時 (0 ～ 23) です。

関連項目

getHours()

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。 次に、getHours() メソッドと getMinutes() メソッドを呼び出し、 時と分を 24 時間形式で取得します。最後に、ストリング localTime を作成し、 関数 getUSClockTime() を呼び出した結果に割り当てます。この関数は、 getHours() と getMinutes() を再度呼び出します。これにより、時間 03:05 PM が表示されます。 最後に、localTime と同様の方法で String 変数 utcTime を作成します。 この場合、結果は同じになります。 

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}

getUTCMilliseconds()メソッド 
AS3 function getUTCMilliseconds():Number

Date オブジェクトのミリ秒 (0 ～ 999 の整数) 部分を世界時 (UTC) で返します。

戻り値
Number — Date オブジェクトの UTC のミリ秒部分です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getUTCMilliseconds() メソッドを呼び出し、 Date オブジェクト now の作成時点の分を UTC で取得します。 

var now:Date = new Date();
trace(now.getUTCMilliseconds());

getUTCMinutes()メソッド 
AS3 function getUTCMinutes():Number

Date オブジェクトの分 (0 ～ 59 の整数) 部分を世界時 (UTC) で返します。

戻り値
Number — Date オブジェクトの UTC の分部分です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getUTCMinutes() メソッドを呼び出し、 Date オブジェクト now の作成時点の分を UTC で取得します。 

var now:Date = new Date();
trace(now.getUTCMinutes());

getUTCMonth()メソッド 
AS3 function getUTCMonth():Number

Date オブジェクトの月 (0 [1 月] ～ 11 [12 月]) 部分を世界時 (UTC) で返します。

戻り値
Number — Date オブジェクトの UTC の月部分です。

関連項目

getMonth()

例
次の例では、新しい Array オブジェクト monthLabels を作成します。エレメントは January ～ December です。また、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getUTCMonth() メソッドを 2 回呼び出します。1 回目は、Date オブジェクト now の月の数値、2 回目は月の名前を UTC で返します。 

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);

getUTCSeconds()メソッド 
AS3 function getUTCSeconds():Number

Date オブジェクトの秒 (0 ～ 59 の整数) 部分を世界時 (UTC) で返します。

戻り値
Number — Date オブジェクトの UTC の秒部分です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getUTCSeconds() メソッドを呼び出し、 Date オブジェクト now の作成時点の分を UTC で取得します。 

var now:Date = new Date();
trace(now.getUTCSeconds());

parse()メソッド 
public static function parse(date:String):Number

日付を表すストリングを、1970 年 1 月 1 日 (UTC) から経過したミリ秒数に相当する数値に変換します。

パラメータ
date:String — Date.toString() の出力形式に準じた日付のストリング表現です。Date.toString() の出力の日付形式は、次のとおりです。 
Day Mon DD HH:MM:SS TZD YYYY

次に例を示します。 

Wed Apr 12 15:30:17 GMT-0700 2006

タイムゾーン指定 (TZD) は、常に GMT-HHMM または UTC-HHMM の形式になります。これは、グリニッジ標準時 (GMT) を基準にした時間と分のオフセットを示します。なお、グリニッジ標準時は現在は世界時 (UTC) とも呼ばれています。年、月、曜日は、スラッシュ (/) またはスペースで区切ることができますが、ダッシュ (-) で区切ることはできません。他にも、次のような形式がサポートされます。月、曜日、年だけというように、これらの形式の一部分を含めることもできます。

MM/DD/YYYY HH:MM:SS TZD
HH:MM:SS TZD Day Mon/DD/YYYY
Mon DD YYYY HH:MM:SS TZD
Day Mon DD HH:MM:SS TZD YYYY
Day Mon Date HH:MM:SS TZD YYYY
MM/DD/YYYY HH:MM:SS TZD
MM/DD/YYYY HH:MM:SS TZD

戻り値
Number — 1970 年 1 月 1 日 (UTC) から経過したミリ秒数を表す数値です。

関連項目

Date.toString()

例
次の例では、1974 年 11 月 30 日の日付ストリングを dateParsed に割り当てます。 次に、Date.parse() メソッドを呼び出し、この日付を 1970 年 1 月 1 日からのミリ秒数に変換します。 
var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // output 155030400000

setDate()メソッド 
AS3 function setDate(day:Number):Number

月内の日付をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

パラメータ
day:Number — 1 ～ 31 の整数です。

戻り値
Number — ミリ秒で表される新しい時刻です。

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。 getDate() メソッドを呼び出し、日付を取得します。次に、 day パラメータに 20 を設定して setDate() を呼び出します。 再度 getDate() を呼び出し、新しく設定された日付を取得します。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20

setFullYear()メソッド 
AS3 function setFullYear(year:Number, month:Number, day:Number):Number

年をローカル時間で設定し、新しい時刻をミリ秒で返します。month パラメータと day パラメータを指定すると、両方はローカル時間に設定されます。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

このメソッドを呼び出しても Date オブジェクトの他のフィールドは変更されませんが、このメソッドを呼び出した結果として曜日が変わった場合には、Date.getUTCDay() と Date.getDay() は新しい値を返すことがあります。

パラメータ
year:Number — 年を示す 4 桁の数値です。2 桁の数値は 4 桁の年の省略形を表しません。たとえば、99 は 1999 年ではなく、99 年です。
 
month:Number — 0 (1 月) ～ 11 (12 月) の整数です。
 
day:Number — 1 ～ 31 の数値です。

戻り値
Number — ミリ秒で表される新しい時刻です。

関連項目

getUTCDay()
getDay()

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。 getFullYear() メソッドを呼び出し、4 桁の年を取得します。 次に、year パラメータに 2000 を設定して setFullYear() を呼び出します。 再度 getFullYear() を呼び出し、新しく設定された年を取得します。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000

setHours()メソッド 
AS3 function setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

時をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

パラメータ
hour:Number — 0 (0 時) ～ 23 (午後 11 時) の整数です。
 
minute:Number — 0 ～ 59 の整数です。
 
second:Number — 0 ～ 59 の整数です。
 
millisecond:Number — 0 ～ 999 の整数です。

戻り値
Number — ミリ秒で表される新しい時刻です。

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。次に、 getHours() メソッドと getMinutes() メソッドを呼び出し、時と分を取得します。次に、hour パラメータに 12 を設定して setHours() を呼び出します。再度 getHours() と getMinutes() を呼び出し、 新しく設定された時と分を取得します。 

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20

setMilliseconds()メソッド 
AS3 function setMilliseconds(millisecond:Number):Number

ミリ秒をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

パラメータ
millisecond:Number — 0 ～ 999 の整数です。

戻り値
Number — ミリ秒で表される新しい時刻です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getMilliseconds() メソッドを呼び出し、 now が作成されたときの分を取得します。次に、minute パラメータに 4 を設定して setMilliseconds() を再度呼び出して、もう 1 つの新しい Date オブジェクト before を作成します。 再度 getMilliseconds() を呼び出し、新しく設定されたミリ秒を取得します。 

var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());

setMinutes()メソッド 
AS3 function setMinutes(minute:Number, second:Number, millisecond:Number):Number

分をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

パラメータ
minute:Number — 0 ～ 59 の整数です。
 
second:Number — 0 ～ 59 の整数です。
 
millisecond:Number — 0 ～ 999 の整数です。

戻り値
Number — ミリ秒で表される新しい時刻です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getMinutes() メソッドを呼び出し、 now が作成されたときの分を取得します。次に、minute パラメータに 0 を設定して setMinutes() を再度呼び出して、もう 1 つの新しい Date オブジェクト before を作成します。 再度 getMinutes() を呼び出し、新しく設定された分を取得します。 

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());

setMonth()メソッド 
AS3 function setMonth(month:Number, day:Number):Number

月と、オプションで日付をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

パラメータ
month:Number — 0 (1 月) ～ 11 (12 月) の整数です。
 
day:Number — 1 ～ 31 の整数です。

戻り値
Number — ミリ秒で表される新しい時刻です。

例
次の例では、新しい Array オブジェクト monthLabels を作成します。エレメントは January ～ December です。また、新しい Month オブジェクト now をパラメータの指定なしで作成します。 次に、getMonth() メソッドを呼び出し、 now が作成されたときの分を取得します。次に、month パラメータに 0 を設定して setMonth() を呼び出します。 再度 getMonth() を呼び出し、新しく設定された月を取得します。 

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January

setSeconds()メソッド 
AS3 function setSeconds(second:Number, millisecond:Number):Number

秒をローカル時間で設定し、新しい時刻をミリ秒で返します。ローカル時間は、Flash Player を実行しているオペレーティングシステムによって決まります。

パラメータ
second:Number — 0 ～ 59 の整数です。
 
millisecond:Number — 0 ～ 999 の整数です。

戻り値
Number — ミリ秒で表される新しい時刻です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getseconds() メソッドを呼び出し、 now が作成されたときの分を取得します。次に、second パラメータに 0 を設定して setSeconds() を呼び出します。 再度 getSeconds() を呼び出し、新しく設定された秒を取得します。 

var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0

setTime()メソッド 
AS3 function setTime(millisecond:Number):Number

日付を 1970 年 1 月 1 日 0 時からのミリ秒数で設定し、新しい時刻をミリ秒で返します。

パラメータ
millisecond:Number — 整数値です。0 は世界時 (UTC) の 1 月 1 日 0 時です。

戻り値
Number — ミリ秒で表される新しい時刻です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、millisecond パラメータに -1292601600000 を設定して setTime() メソッドを呼び出します。これにより、時刻は Tue Jan 15 00:00:00 GMT-0800 1929 に設定されます。 

var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929

setUTCDate()メソッド 
AS3 function setUTCDate(day:Number):Number

月内の日付を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。このメソッドを呼び出しても、Date オブジェクトの他のフィールドは変更されませんが、このメソッドを呼び出した結果として曜日が変わった場合には、Date.getUTCDay() メソッドと Date.getDay() メソッドは新しい値を返すことがあります。

パラメータ
day:Number — 1 ～ 31 の整数値です。

戻り値
Number — ミリ秒で表される新しい時刻です。

関連項目

getUTCDay()
getDay()

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。メソッド getUTCDate() メソッドを呼び出すと、月内の日付が正しく返されます。次に、day パラメータに 1 を設定して setUTCDate() を呼び出します。trace() ステートメントで、 日付が正しく設定されたことを確認します。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974

setUTCFullYear()メソッド 
AS3 function setUTCFullYear(year:Number, month:Number, day:Number):Number

年を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。

このメソッドでは、オプションで月と日を設定することもできます。このメソッドを呼び出しても他のフィールドは変更されませんが、このメソッドを呼び出した結果として曜日が変わった場合には、Date.getUTCDay() と Date.getDay() メソッドは新しい値を返すことがあります。

パラメータ
year:Number — 4 桁の年 (2000 など) を表す整数です。
 
month:Number — 0 (1 月) ～ 11 (12 月) の整数です。
 
day:Number — 1 ～ 31 の整数です。

戻り値
Number — 整数です。

関連項目

getUTCDay()
getDay()

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。メソッド getUTCFullYear() を呼び出すと、4 桁の年が正しく返されます。次に、year パラメータに 1975 を設定して setUTCFullYear() を呼び出します。trace() ステートメントで、 年が正しく設定されたことを確認します。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975

setUTCHours()メソッド 
AS3 function setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

時を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。オプションで、分、秒、およびミリ秒を指定することができます。

パラメータ
hour:Number — 0 (0 時) ～ 23 (午後 11 時) の整数です。
 
minute:Number — 0 ～ 59 の整数です。
 
second:Number — 0 ～ 59 の整数です。
 
millisecond:Number — 0 ～ 999 の整数です。

戻り値
Number — ミリ秒で表される新しい時刻です。

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) を指定します。次に、 メソッド getHours()、getMinutes()、getUTCHours()、および getUTCMinutes() を呼び出し、 時と分を取得します。次に、hour パラメータに 12 を設定して setUTCHours() を呼び出します。メソッド getHours()、 getMinutes()、getUTCHours()、および getUTCMinutes() を再度呼び出すと、 更新された時が正しく表示されます。 

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20

setUTCMilliseconds()メソッド 
AS3 function setUTCMilliseconds(millisecond:Number):Number

ミリ秒を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。

パラメータ
millisecond:Number — 0 ～ 999 の整数です。

戻り値
Number — ミリ秒で表される新しい時刻です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getUTCMilliseconds() メソッドを呼び出し、 now が作成されたときの分を取得します。次に、minute パラメータに 4 を設定して setUTCMilliseconds() を呼び出して、もう 1 つの新しい Date オブジェクト before を作成します。 再度 getUTCMilliseconds() を呼び出し、新しく設定されたミリ秒を取得します。 


var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());

setUTCMinutes()メソッド 
AS3 function setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number

分を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。オプションで、秒とミリ秒を指定することができます。

パラメータ
minute:Number — 0 ～ 59 の整数です。
 
second:Number — 0 ～ 59 の整数です。
 
millisecond:Number — 0 ～ 999 の整数です。

戻り値
Number — ミリ秒で表される新しい時刻です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getUTCMinutes() メソッドを呼び出し、 now が作成されたときの分を取得します。次に、minute パラメータに 0 を設定して setUTCMinutes() を呼び出して、もう 1 つの新しい Date オブジェクト before を作成します。 再度 getUTCMinutes() を呼び出し、新しく設定された分を取得します。 

var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());

setUTCMonth()メソッド 
AS3 function setUTCMonth(month:Number, day:Number):Number

月、およびオプションで日を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。このメソッドを呼び出しても他のフィールドは変更されませんが、このメソッドを呼び出した結果として曜日が変わった場合には、Date.getUTCDay() メソッドと Date.getDay() メソッドは新しい値を返すことがあります。

パラメータ
month:Number — 0 (1 月) ～ 11 (12 月) の整数です。
 
day:Number — 1 ～ 31 の整数です。

戻り値
Number — ミリ秒で表される新しい時刻です。

関連項目

getDay()

例
次の例では、新しい Array オブジェクト UTCMonthLabels を作成します。エレメントは January ～ December です。また、新しい UTCMonth オブジェクト now をパラメータの指定なしで作成します。 次に、getUTCMonth() メソッドを呼び出し、 now が作成されたときの分を取得します。次に、month パラメータに 0 を設定して setUTCMonth() を呼び出します。 再度 getUTCMonth() を呼び出し、新しく設定された月を取得します。 

var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January

setUTCSeconds()メソッド 
AS3 function setUTCSeconds(second:Number, millisecond:Number):Number

秒、およびオプションでミリ秒を世界時 (UTC) で設定し、新しい時刻をミリ秒で返します。

パラメータ
second:Number — 0 ～ 59 の整数です。
 
millisecond:Number — 0 ～ 999 の整数です。

戻り値
Number — ミリ秒で表される新しい時刻です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getUTCSeconds() メソッドを呼び出し、 now が作成されたときの分を取得します。次に、second パラメータに 0 を設定して setUTCSeconds() を呼び出します。再度 getUTCSeconds() を呼び出し、新しく設定された 秒を取得します。 

var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0

toDateString()メソッド 
AS3 function toDateString():String

曜日と日付のみのストリング表現を返します。時刻またはタイムゾーンは含まれません。次のメソッドと対照を成します。

戻り値
String — 曜日と日付のみのストリング表現です。

関連項目

toString()

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、trace() ステートメント内で次のメソッドを呼び出します。 

var now:Date = new Date();
trace(now);
trace(now.toDateString());

toLocaleDateString()メソッド 
AS3 function toLocaleDateString():String

曜日と日付のみのストリング表現を返します。時刻またはタイムゾーンは含まれません。このメソッドは、Date.toDateString と同じ値を返します。次のメソッドと対照を成します。

戻り値
String — 曜日と日付のみの String 表現です。

関連項目

toDateString()
toTimeString()
toString()
toLocaleString()メソッド 
AS3 function toLocaleString():String

曜日、日付、時刻のストリング表現を、指定されたローカル時間で返します。同じ情報 (およびタイムゾーン) をストリングの最後に年を付けて返す Date.toString() メソッドと対照を成します。

戻り値
String — Date オブジェクトのストリング表現をローカルタイムゾーンで返します。
toLocaleTimeString()メソッド 
AS3 function toLocaleTimeString():String

時刻のみのストリング表現を返します。曜日、日付、年、またはタイムゾーンは含まれません。時刻とタイムゾーンを返す Date.toTimeString() メソッドと対照を成します。

戻り値
String — 時刻とタイムゾーンのみのストリング表現です。

関連項目

toTimeString()
toString()メソッド 
AS3 function toString():String

曜日、日付、時刻、およびタイムゾーンのストリング表現を返します。出力の日付形式は、次のとおりです。 

Day Mon Date HH:MM:SS TZD YYYY

次に例を示します。

Wed Apr 12 15:30:17 GMT-0700 2006

戻り値
String — Date オブジェクトのストリング表現です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、trace() ステートメント内で toString を呼び出し、 now が作成された時点の now のすべてのパラメータを表示します。 


var now:Date = new Date();
trace(now);

toTimeString()メソッド 
AS3 function toTimeString():String

時刻とタイムゾーンのみのストリング表現を返します。曜日と日付は含まれません。曜日と日付のみを返す Date.toDateString() メソッドと対照を成します。

戻り値
String — 時刻とタイムゾーンのみのストリング表現です。

関連項目

toDateString()
toUTCString()メソッド 
AS3 function toUTCString():String

曜日、日付、および時刻のストリング表現を世界時 (UTC) で返します。たとえば、2005 年 2 月 1 日を Tue Feb 1 00:00:00 2005 UTC として返します。

戻り値
String — Date オブジェクトの UTC のストリング表現です。

関連項目

toString()
UTC()メソッド 
public static function UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number

1970 年 1 月 1 日 0 時 (世界時) からパラメータで指定された時刻までのミリ秒数を返します。このメソッドでは世界時を使用するのに対し、Date コンストラクタではローカル時間を使用します。

このメソッドは、UTC の日付を Date クラスのコンストラクタに渡す場合に便利です。Date クラスのコンストラクタはミリ秒オフセットを引数として受け取るため、Date.UTC() メソッドを使用して UTC の日付を対応のミリ秒オフセットに変換し、このオフセットを引数として Date クラスコンストラクタに送ることができます。

パラメータ
year:Number — 年を表す 4 桁の整数 (2000 など) です。
 
month:Number — 0 (1 月) ～ 11 (12 月) の整数です。
 
date:Number (default = 1) — 1 ～ 31 の整数です。
 
hour:Number (default = 0) — 0 (0 時) ～ 23 (午後 11 時) の整数です。
 
minute:Number (default = 0) — 0 ～ 59 の整数です。
 
second:Number (default = 0) — 0 ～ 59 の整数です。
 
millisecond:Number (default = 0) — 0 ～ 999 の整数です。

戻り値
Number — 1970 年 1 月 1 日から指定された日時までのミリ秒数です。

例
次の例では、新しい Date オブジェクト someBirthday を作成します。パラメータには、 year (1974)、month (10 = 11 月)、day (30)、hour (1)、および minute (20) をローカル時間で 指定します。次に、setTime() メソッド内で UTC() を呼び出し、これらのパラメータを世界時に リセットします。 

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());

valueOf()メソッド 
AS3 function valueOf():Number

Date オブジェクトの 1970 年 1 月 1 日 0 時 (世界時) からのミリ秒数を返します。

戻り値
Number — Date オブジェクトが表す 1970 年 1 月 1 日からのミリ秒数です。

例
次の例では、新しい Date オブジェクト now をパラメータの指定なしで作成します。 次に、getTime() メソッドを呼び出し、 now が作成された時刻から 1970 年 1 月 1 日 0 時までのミリ秒数を取得します。 次に、valueOf() を呼び出し、同じ値を取得します。 


var now:Date = new Date();
trace(now.getTime());
trace(now.valueOf());

例

次の例では、下に示す変数を割り当てる場合の Date() コンストラクタのさまざまな 使用法を示しています。 

package {
    import flash.display.Sprite;
    
    public class DateExample extends Sprite{
        public function DateExample() {
            var myDate1:Date = new Date();
            trace(myDate1); // [NOW]

            var myDate2:Date = new Date(2000, 0, 1);
            trace(myDate2); // Sat Jan 1 00:00:00 GMT-0800 2000

            var myDate3:Date = new Date(65, 2, 6, 9, 30, 15, 0);
            trace(myDate3); // Sat Mar 6 09:30:15 GMT-0800 1965

            var myDate4:Date = new Date(-14159025000);
            trace(myDate4); // Sun Jul 20 19:56:15 GMT-0700 1969
        }        
    }    
}



© 2004-2006 Adobe Systems Incorporated. All rights reserved.
2006.08.17, 午後 11:21, GMT-07:00