BitmapData オブジェクトが参照されます。

ビットマップオブジェクトが最も近いピクセルに吸着されるかどうかを指定します。PixelSnapping クラスには正の値が入ります。

• PixelSnapping.NEVER—ピクセルは吸着されません。
• PixelSnapping.ALWAYS—イメージは、変換とは関係なく常に最も近いピクセルに吸着されます。
• PixelSnapping.AUTO—イメージが回転または傾斜なしで描画され、99.9% から 100.1% の倍率で描画される場合、イメージは最も近いピクセルに吸着されます。これらの条件が満たされる場合、ビットマップイメージは 100% の倍率で描画され、最も近いピクセルに吸着されます。内部的には、この値によって、ベクターレンダラを使ってイメージが可能な限り高速に描画されます。

ビットマップを拡大 / 縮小するときにスムージングするかどうかを指定します。true である場合、ビットマップは拡大 / 縮小時にスムージングされます。false である場合、ビットマップは拡大 / 縮小時にスムージングされません。

指定された BitmapData オブジェクトを参照するようにビットマップオブジェクトを初期化します。

	bitmapData:BitmapData (default = null) — BitmapData オブジェクトが参照されます。
	pixelSnapping:String (default = "auto") — ビットマップオブジェクトが最も近いピクセルに吸着されるかどうかを示します。
	smoothing:Boolean (default = false) — ビットマップを拡大 / 縮小するときにスムージングするかどうかを示します。たとえば、次の例は同じビットマップを 3 倍に拡大した場合に、smoothing を false に設定したもの (左) と true に設定したもの (右) です。

1. プロパティ url を作成します。これはイメージファイルの場所と名前です。
2. クラスコンストラクタが configureAssets() メソッドを呼び出します。続いて、このメソッドでは completeHandler() メソッドを経由して提供される情報が出力されます。
3. configureAssets() が Loader オブジェクトを作成します。 これは、completeHandler() がイメージの操作を完了したときに送出されるイベントリスナーをインスタンス化します。
4. 次に、buildChild() メソッドが URLRequest オブジェクト の新しいインスタンス request を作成して、ファイル名と場所を認識させるために url を渡します。
5. request オブジェクトが loader.load() メソッドに渡されます。このメソッドにより、 イメージが表示オブジェクトを経由してメモリにロードされます。
6. 次にイメージが表示リストに配置され、イメージは直ちに 画面の座標 x = 0、y = 0 に表示されます。
7. 続いて、completeHandler() メソッドで、次の処理が実行されます。
1. 2 番目の Loader オブジェクトと Bitmap オブジェクトを作成します。Bitmap オブジェクトは、この Loader オブジェクトで Bitmap オブジェクトを作成します。
2. 2 番目のBitmap オブジェクト duplicate を作成し、 duplicateImage() メソッドを呼び出して、元のイメージの複製を作成します。
3. BitmapData オブジェクトを作成し、duplicate オブジェクトの BitmapData オブジェクトに割り当てます。
4. 元のイメージと同じ座標、幅、高さで初期化された新しい Rectangle オブジェクトを 作成します。
5. 新しい Point オブジェクトを作成します。デフォルトでは x = 0、y = 0 に作成されます。
6. 次に示す変数を作成します。
• operation: しきい値が元の値以上である場合に、 新しい色を適用します。
• threshold: 各ピクセルの比較対象である値は、 アルファ 0xCC の明るい灰色に設定されます。
• color: しきい値のテストに合格したピクセルに設定される色です。 この場合は黄色です。
• mask: 正反対の色に設定します。この場合は透明色の青色です。
• copySource: false に設定されます。これは、しきい値を満たさなかった場合に、 ピクセル値がコピーされないことを示します。イメージが複製され、 しきい値のテストに合格したピクセルだけが変更されるため、この値に意味はありません。
7. 上記の変数を使用して threshold() メソッドを呼び出します。結果のしきい値の等式は 次のようになります。 if (current pixel Value & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) then set pixel to 0xFFFFFF00.

メモ :

• [ローカルでの再生に関するセキュリティ] を [ローカルファイルにのみアクセスする] に設定して SWF ファイルをコンパイルする必要があります。
• この例では、"Image.gif" という名前のファイルが SWF ファイルと同じディレクトリに配置されている必要があります。
• イメージは、幅が 80 ピクセル以内のものを使用することをお勧めします。

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}