load() メソッドを使用してロードされた SWF ファイルまたはイメージ (JPG、PNG、または GIF) ファイルのルート表示オブジェクトが含まれます。

関連項目

ロードされているオブジェクトに対応する LoaderInfo オブジェクトを返します。LoaderInfo オブジェクトは Loader オブジェクトとロードされたコンテンツオブジェクトとの間で共有されます。LoaderInfo オブジェクトは、ロードの進行状況に関する情報と、ロードされたファイルに関する統計を提供します。

関連項目

SWF、JPEG、GIF、または PNG ファイルなどのファイルをロードするのに使用できる Loader オブジェクトを作成します。アセットを Loader インスタンスの子としてロードするには、load() メソッドを呼び出します。その後、Loader オブジェクトを表示リストに追加できます。たとえば、DisplayObjectContainer インスタンスの addChild() メソッドを使用して追加します。アセットはロードされるとステージに表示されます。

Loader インスタンスを "リスト外" で、つまり、表示リスト上の表示オブジェクトコンテナに追加せずに使用することもできます。このモードの場合、Loader インスタンスを使用して、アプリケーションの追加モジュールを含む SWF ファイルをロードすることができます。

SWF ファイルのロードが完了したことを検出するには、Loader オブジェクトの contentLoaderInfo プロパティに関連付けられた LoaderInfo オブジェクトのイベントを使用できます。その時点で、モジュール SWF ファイル内のコードを実行して、モジュールを初期化し、開始することができます。リスト外モードでは、Loader インスタンスを使用して、コンポーネントまたはメディアアセットを含む SWF ファイルをロードすることもできます。この場合も、LoaderInfo オブジェクトのイベント通知を使用して、コンポーネントのロードが完了したことを検出できます。その時点で、アプリケーションは SWF ファイルのライブラリ内のコンポーネントとメディアアセットの使用を開始できます。これは、それらのコンポーネントとアセットを表す ActionScript 3.0 クラスをインスタンス化することによって行います。

Loader オブジェクトの状態を判別するには、Loader オブジェクトの contentLoaderInfo プロパティに関連付けられた LoaderInfo オブジェクトの次のイベントを監視します。

• open イベントは、ロードが開始したときに送出されます。
• ioError または securityError イベントは、ファイルをロードできない場合、あるいはロード処理中にエラーが発生した場合に送出されます。
• progress イベントは、ファイルがロードされている間、継続的に発生します。
• complete イベントは、ファイルのダウンロードが完了したときに送出されます。ただし、この時点では、ロードされたムービークリップのメソッドとプロパティはまだ使用できません。
• init イベントは、ロードされた SWF ファイルのプロパティおよびメソッドにアクセスできるようになると、送出されます。そのため、ロードされた SWF ファイルに対して各種の操作を開始できます。このイベントは、complete ハンドラの前に送出されます。ストリーミング SWF ファイルの場合、init イベントは complete イベントよりもかなり前に発生することがあります。ほとんどの場合、init ハンドラを使用します。

関連項目

Loader インスタンスに対して現在進行中の load() メソッドの処理をキャンセルします。

関連項目

SWF、JPEG、プログレッシブ JPEG、非アニメーション GIF、または PNG ファイルを、この Loader オブジェクトの子であるオブジェクトにロードします。アニメーション GIF ファイルを読み込むと、先頭のフレームのみ表示されます。Loader オブジェクトには子を 1 つだけしか含めることができないため、後続の load() 要求を発行すると直前の要求 (保留中であれば) を終了し、新たにロードを開始します。

Loader オブジェクトにロードした SWF ファイルまたはイメージは、その Loader オブジェクトの親の表示オブジェクトの位置、回転、および拡大/縮小の各プロパティを継承します。

このメソッドを使用してロードされたムービーまたはイメージを削除したり、進行中のロード処理をキャンセルするには、unload() メソッドを使用します。

load() メソッドを使用するときは、Flash Player セキュリティモデルを考慮してください。

• コンテンツは、アクセスできるソースであればどのソースからでもロードできます。
• 呼び出し元 SWF ファイルがネットワーク上のサンドボックスにあり、ロードするファイルがローカルにある場合、ロードできません。
• ロードされたコンテンツが SWF ファイルの場合、別のセキュリティ Sandbox にある SWF ファイルでそれをスクリプト処理することはできません。ただし、ロードされたコンテンツファイルで、Security.allowDomain() メソッドの呼び出しによってクロススクリプトに関する取り決めが承認されていた場合は可能です。
• ActionScript 1.0 または 2.0 で作成された SWF ファイル (AVM1Movie オブジェクトとしてロードされる) は、ActionScript 3.0 で作成された SWF ファイル (Sprite または MovieClip オブジェクトとしてロードされる) をクロススクリプトすることはできません。LocalConnection クラスを使用して、これらのファイルが互いに通信するようにできます。
• ロードされたコンテンツがイメージの場合、セキュリティ Sandbox の外にある SWF ファイルからそのデータにアクセスすることはできません。ただし、その SWF ファイルのドメインがイメージの元のドメインにあるクロスドメインポリシーファイルに含まれていた場合は可能です。
• ローカルファイルシステムのサンドボックスにあるムービークリップでは、ネットワーク接続したローカルのサンドボックスにあるムービークリップをクロススクリプトできません。その逆も同様です。

詳細については、次のトピックを参照してください。

• 『ActionScript 3.0 のプログラミング』のセキュリティの章と LiveDocs の最新コメント
• Flash Player 9 セキュリティに関するホワイトペーパー

関連項目

ByteArray オブジェクトに保管されているバイナリデータからロードします。

関連項目

load() メソッドを使用してロードされた、この Loader オブジェクトの子を削除します。関連した LoaderInfo オブジェクトの property は null にリセットされます。他のオブジェクトが参照している可能性があるため、子は必ずしも破棄されるとは限りません。しかし、Loader オブジェクトの子ではなくなります。

子 SWF ファイルをアンロードする前に、LocalConnection、NetConnection、NetStream、Sound オブジェクトなど、子 SWF ファイルのオブジェクト内のストリームをすべて明示的に閉じておくことをお勧めします。そうしなかった場合は、子 SWF ファイルがアンロードされた後も、子 SWF ファイルのオーディオの再生が続く場合があります。子 SWF ファイルのストリームを閉じるには、unload イベントを受け取る子にイベントリスナーを追加します。親が Loader.unload() を呼び出すと、unload イベントが子に対して送出されます。次のコードは、このような処理を行う例を示します。

function closeAllStreams(evt:Event) {
myNetStream.close();
mySound.close();
myNetConnection.close();
myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

関連項目

1. url プロパティを作成します。これはイメージファイルの場所と名前です。
2. LoaderExample コンストラクタでは、loader という名前の新しい Loader オブジェクトが 作成され、手順 3 で説明する configureListeners() メソッドに渡されます。
3. コンストラクタは URLRequest オブジェクトの新しいインスタンス、 request を作成して、ファイル名と場所が分かるように、url を渡します。
4. request オブジェクトが loader オブジェクトの load() メソッドに渡されます。これにより、イメージが表示リストにロードされます。
5. clickHandler イベントリスナーがローダーの click イベントに対して登録されます。 マウスをクリックすると、ロードされたイメージはアンロードされます。
6. configureListeners() メソッドは、次のメソッドを使用して、7 つのイベントリスナーを追加します。
• completeHandler() メソッドは、イメージのロードが完了したときに実行されます。
• httpStatusHandler() メソッドは、イメージがローカルにロードされない場合で、 ネットワーク要求を行うことができ、Flash Player がそれを検出できる場合にのみ実行されます。
• initHandler() メソッドは、completeHandler() メソッドの前、 かつ progressHandler() メソッドの後に実行されます。通常、SWF ファイルをロードする場合は init イベントの方が便利です。
• ioErrorHandler() メソッドは、イメージファイルを使用できないか、イメージファイルにアクセスできない場合に 実行されます。
• openHandler() メソッドは、イメージファイルが最初に開かれたときに実行されます。
• progressHandler() メソッドは、イメージファイルのロードが開始したときに実行され、 イメージのロードが完了したときに再び実行されます。
• unLoadHandler() メソッドは、ユーザーがイメージをクリックしたときに unload() メソッドを使用してイメージがアンロードされた場合に実行されます。

次の要件に注意してください。

• この例では、Image.gif という名前のファイルがコンパイル済み SWF ファイルと同じディレクトリに配置されている必要があります。 メイン SWF ファイルのサイズ内に収まる領域を持つイメージを使用します。
• この例は、LoaderInfo オブジェクトで使用可能なすべてのイベントを利用しますが、ほとんどの場合、 必要になるのは 1 つのサブセットのみです。特に、イメージファイルをロードするだけの場合は、ローカルイメージをロードするときの complete イベント (および必要に応じて ioError イベント) で十分です。

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}