flash.events.TextEvent (Flex™ 2 リファレンスガイド)

	プロパティ	定義
		bubbles : Boolean イベントがバブリングイベントかどうかを示します。	Event
		cancelable : Boolean イベントに関連付けられたビヘイビアを回避できるかどうかを示します。	Event
		constructor : Object 特定のオブジェクトインスタンスのクラスオブジェクトまたはコンストラクタ関数への参照です。	Object
		currentTarget : Object イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。	Event
		eventPhase : uint イベントフローの現在の段階です。	Event
		prototype : Object [static] クラスまたは関数オブジェクトのプロトタイプオブジェクトへの参照です。	Object
		target : Object イベントターゲットです。	Event
		text : String `textInput` イベントの場合は、ユーザーが入力した文字または文字のシーケンスです。	TextEvent
		type : String イベントの型です。	Event

	メソッド	定義
		TextEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, text:String = "") テキストイベントに関する情報を含む Event オブジェクトを作成します。	TextEvent
		clone():Event TextEvent オブジェクトのコピーを作成して、各プロパティの値を元のプロパティの値と一致するように設定します。	TextEvent
		formatToString(className:String, ... arguments):String カスタム Event クラスに `toString()` メソッドを実装するためのユーティリティ関数です。	Event
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isDefaultPrevented():Boolean イベントで `preventDefault()` が呼び出されたかどうかをチェックします。	Event
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメータとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		preventDefault():void イベントのデフォルトビヘイビアをキャンセルできる場合に、そのビヘイビアをキャンセルします。	Event
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙可能かどうかを示します。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		stopImmediatePropagation():void イベントフローの現在のノードおよび後続するノードで、イベントリスナーが処理されないようにします。	Event
		stopPropagation():void イベントフローの現在のノードに後続するノードで、イベントリスナーが処理されないようにします。	Event
		toString():String TextEvent オブジェクトのすべてのプロパティを含むストリングを返します。	TextEvent
		valueOf():Object 指定されたオブジェクトのプリミティブ値を返します。	Object

パブリック定数

	定数		定義
		ACTIVATE : String = "activate" [static] `activate` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		ADDED : String = "added" [static] `added` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		CANCEL : String = "cancel" [static] `cancel`イベントオブジェクトの `type` プロパティの値を定義します。	Event
		CHANGE : String = "change" [static] `change` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		CLOSE : String = "close" [static] `close` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		COMPLETE : String = "complete" [static] `complete` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		CONNECT : String = "connect" [static] `connect` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		DEACTIVATE : String = "deactivate" [static] `deactivate` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		ENTER_FRAME : String = "enterFrame" [static] `enterFrame` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		ID3 : String = "id3" [static] `id3` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		INIT : String = "init" [static] `init` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		LINK : String = "link" [static] `link` イベントオブジェクトの `type` プロパティの値を定義します。	TextEvent
		MOUSE_LEAVE : String = "mouseLeave" [static] `mouseLeave` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		OPEN : String = "open" [static] `open` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		REMOVED : String = "removed" [static] `removed` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		RENDER : String = "render" [static] `render` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		RESIZE : String = "resize" [static] `resize` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		SCROLL : String = "scroll" [static] `scroll` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		SELECT : String = "select" [static] `select` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		SOUND_COMPLETE : String = "soundComplete" [static] `soundComplete` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		TAB_CHILDREN_CHANGE : String = "tabChildrenChange" [static] `tabChildrenChange` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		TAB_ENABLED_CHANGE : String = "tabEnabledChange" [static] `tabEnabledChange` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		TAB_INDEX_CHANGE : String = "tabIndexChange" [static] `tabIndexChange` イベントオブジェクトの `type` プロパティの値を定義します。	Event
		TEXT_INPUT : String = "textInput" [static] `textInput` イベントオブジェクトの `type` プロパティの値を定義します。	TextEvent
		UNLOAD : String = "unload" [static] `unload` イベントオブジェクトの `type` プロパティの値を定義します。	Event

プロパティの詳細

text

プロパティ

text:String [read-write]

textInput イベントの場合は、ユーザーが入力した文字または文字のシーケンスです。link イベントの場合は、<a> タグの href 属性の event 属性のテキストです。

実装
public function get text():String
public function set text(value:String):void

例
次のコードは、ユーザーがハイパーテキストリンクをクリックしたときに送出される link イベントを示します。

 import flash.text.TextField;
 import flash.events.TextEvent;   
 
 var tf:TextField = new TextField();
 tf.htmlText = "<a href='event:myEvent'>Click Me.</a>";
 tf.addEventListener("link", clickHandler);
 addChild(tf);
 
 function clickHandler(e:TextEvent):void {
  trace(e.type); // link
  trace(e.text); // myEvent
 }

コンストラクタの詳細

TextEvent

()

コンストラクタ

public 関数 TextEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, text:String = "")

テキストイベントに関する情報を含む Event オブジェクトを作成します。イベントリスナーには Event オブジェクトがパラメータとして渡されます。

パラメータ

	`type:String` — イベントのタイプです。イベントリスナーは、継承された `type` プロパティを通じてこの情報にアクセスできます。有効な値は次のとおりです。`TextEvent.LINK` および `TextEvent.TEXT_INPUT` です。

	`bubbles:Boolean` (default = `false`) — Event オブジェクトがイベントフローのバブリング段階で処理されるかどうかを判断します。イベントリスナーは、継承された `bubbles` プロパティを通じてこの情報にアクセスできます。

	`cancelable:Boolean` (default = `false`) — Event オブジェクトがキャンセル可能かどうかを判断します。イベントリスナーは、継承された `cancelable` プロパティを通じてこの情報にアクセスできます。

	`text:String` (default = "") — ユーザーが入力したテキストの 1 つ以上の文字です。イベントリスナーは、`text` プロパティを通じてこの情報にアクセスできます。

プロパティ	値
`bubbles`	`true`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	クリックされたハイパーリンクを含むテキストフィールドです。`target` は、必ずしもイベントリスナーを登録した表示リスト内のオブジェクトとは限りません。現在イベントを処理している表示リスト内のオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。
`text`	"event:" の後の URL の残りの部分は、

プロパティ	値
`bubbles`	`true`
`cancelable`	`true`。`preventDefault()` メソッドを呼び出してデフォルトの動作を取り消します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	文字が入力されるテキストフィールドです。target は、必ずしもイベントリスナーを登録した表示リスト内のオブジェクトとは限りません。現在イベントを処理している表示リスト内のオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。
`text`	ユーザーが入力した文字または文字の連続です。

関連項目

flash.text.TextField.textInput
text

例

次の例では、TextEventExample クラスを使用して、テキストフィールドを作成し、それらのテキストフィールドに対するさまざまなテキストイベントを受け取ります。この例では、次の処理を実行します。

後で使用する 2 つの URL の定数を宣言します。
後で使用する TextField 型の 2 つの変数を宣言します。
クラスコンストラクタが次の 2 つのメソッドを呼び出します。

init() : TextField オブジェクトを初期化し、イベントリスナーを追加します。
draw() : TextFields を表示リストに追加し、表示するテキストを割り当てます。

リスナーである linkHandler() および textInputHandler() が、イベントタイプに応じてイベントに反応します。linkHandler() メソッドは、まだ開いていない場合は Web ブラウザを開き、クリックされた URL に移動します。textInputHandler() メソッドは、関連するテキストフィールドでキーが押されるたびに情報を表示します。

メモ :この例に示すドメインは架空のものです。 [yourDomain] は、実際のドメインに置き換える必要があります。

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;
    import flash.text.TextFieldAutoSize;
    import flash.events.TextEvent;
    import flash.events.TextEvent;
    import flash.net.URLRequest;
    import flash.net.navigateToURL;
    
    public class TextEventExample extends Sprite {
        private const DOMAIN_1_URL:String = "http://www.[yourDomain].com";
        private const DOMAIN_2_URL:String = "http://www.[yourDomain].com";
        private var linkTxt:TextField;
        private var textInputTxt:TextField;
        
        public function TextEventExample() {
            init();
            draw();
        }
        
        private function init():void {
            linkTxt = new TextField();
            linkTxt.addEventListener(TextEvent.LINK, linkHandler);
            linkTxt.height = 60;
            linkTxt.autoSize = TextFieldAutoSize.LEFT;            
            linkTxt.multiline = true;
                
            textInputTxt = new TextField();
            textInputTxt.addEventListener(TextEvent.TEXT_INPUT, textInputHandler);
            textInputTxt.type = TextFieldType.INPUT;
            textInputTxt.background = true;
            textInputTxt.border = true;
            textInputTxt.height = 20;            
        }
        
        private function draw():void {
            addChild(linkTxt);
            linkTxt.htmlText += createLink(DOMAIN_1_URL, "Click to go to first domain");
            linkTxt.htmlText += "<br />";
            linkTxt.htmlText += createLink(DOMAIN_2_URL, "Click to go to second domain");

            addChild(textInputTxt);
            textInputTxt.y = linkTxt.height;
            textInputTxt.text = "type here";
        }
        
        private function createLink(url:String, text:String):String {
            var link:String = "";
            link += "<font color='#0000FF'>";
            link += "<u>";
            link += "<b>";
            link += "<a href='event:" + url + "'>" + text + "</a>";
            link += "</b>";
            link += "</u>";
            link += "</font>";
            return link;
        }
        
        private function linkHandler(e:TextEvent):void {
            var request:URLRequest = new URLRequest(e.text);
            navigateToURL(request);
        }
        
        private function textInputHandler(e:TextEvent):void {
            trace(">> ============================");
            trace(">> e.text: " + e.text);
            trace(">> textInputTxt.text: " + textInputTxt.text);
        }
    }
}

Adobe^® Flex™ 2 リファレンスガイド		すべてのパッケージ \| すべてのクラス \| 言語エレメント \| 索引 \| 付録 \| 規則 \| フレーム内に表示フレームなしバージョン
Class TextEvent	プロパティ \| メソッド \| 定数 \| 例

パッケージ	flash.events
	public class TextEvent
継承	TextEvent Event Object
Subclasses	DataEvent, ErrorEvent, IMEEvent