| パッケージ | flash.net |
| public final class URLLoaderDataFormat | |
| 継承 | URLLoaderDataFormat  Object |
| 定数 | 定義 | ||
|---|---|---|---|
| BINARY : String = "binary" [static]
ダウンロードされるデータを生のバイナリデータとして受信することを指定します。
| URLLoaderDataFormat | ||
| TEXT : String = "text" [static]
ダウンロードされるデータをテキストとして受信することを指定します。
| URLLoaderDataFormat | ||
| VARIABLES : String = "variables" [static]
ダウンロードされるデータを URL エンコード形式の変数として受信することを指定します。
| URLLoaderDataFormat | ||
| BINARY | 定数 |
継承されるパブリックプロパティの非表示
継承されるパブリックプロパティの表示
public static const BINARY:String = "binary"ダウンロードされるデータを生のバイナリデータとして受信することを指定します。
| TEXT | 定数 |
public static const TEXT:String = "text"ダウンロードされるデータをテキストとして受信することを指定します。
| VARIABLES | 定数 |
public static const VARIABLES:String = "variables"ダウンロードされるデータを URL エンコード形式の変数として受信することを指定します。
loader という URLLoader インスタンスと
request という URLRequest インスタンスを作成します。これはロードされるファイルの場所と名前です。loader オブジェクトは、configureListeners() メソッドに渡されます。これは
サポートされる各 URLLoader イベントにリスナーを追加します。completeHandler() は complete イベントをリッスンします。このイベントは
"TextFile.txt" が正常にロードされた後に送出されます。openHandler() は open イベントをリッスンします。このイベントは
"TextFile.txt" の (Flash Player への) ダウンロードの開始時に送出されます。progressHandler() は progress イベントをリッスンします。このイベントは
ダウンロード処理を実行中にデータが受信されると送出されます。securityErrorHandler() は securityError イベントをリッスンします。このイベントは
テキスト ファイルが、誤ったローカルでの再生に関するセキュリティ設定でアクセスされた場合に送出されます。httpStatusHandler() は httpStatusHandler イベントをリッスンします。この場合では、このイベントは
"TextFile.txt" がローカルであるため送出されません。ioErrorHandler() は ioError イベントをリッスンします。このイベントは
たとえばファイルが存在しないなど、ファイルに深刻な問題がある場合に発生します。request オブジェクトが、テキストファイルをロードする loader.load() に渡されます。
DisplayObject オブジェクトを使用して、テキストファイルをメモリにロードします。メモ :
package {
import flash.display.Sprite;
import flash.events.*;
import flash.net.*;
public class URLLoaderDataFormatExample extends Sprite {
private var source:String = "TextFile.txt";
private var dataFormat:String = URLLoaderDataFormat.TEXT;
public function URLLoaderDataFormatExample () {
var loader:URLLoader = new URLLoader();
loader.dataFormat = dataFormat;
configureListeners(loader);
var request:URLRequest = new URLRequest(source);
try {
loader.load(request);
} catch (error:Error) {
trace("Error loading requested document: " + source);
}
}
private function configureListeners(dispatcher:URLLoader):void {
dispatcher.addEventListener(Event.COMPLETE, completeHandler);
dispatcher.addEventListener(Event.OPEN, openHandler);
dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
}
private function completeHandler(event:Event):void {
var loader:URLLoader = URLLoader(event.target);
switch(loader.dataFormat) {
case URLLoaderDataFormat.TEXT :
trace("completeHandler (text): " + loader.data);
break;
case URLLoaderDataFormat.BINARY :
trace("completeHandler (binary): " + loader.data);
break;
case URLLoaderDataFormat.VARIABLES :
trace("completeHandler (variables): " + loader.data);
break;
}
}
private function httpStatusHandler(event:Event):void {
trace("httpStatusHandler: " + event);
}
private function ioErrorHandler(event:IOErrorEvent):void {
trace("ioErrorHandler: " + event);
}
private function openHandler(event:Event):void {
trace("openHandler: " + event);
}
private function progressHandler(event:ProgressEvent):void {
trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
}
private function securityErrorHandler(event:SecurityErrorEvent):void {
trace("securityErrorHandler: " + event);
}
}
}