Video.deblocking

Availability

Flash Player 6.
Flash Media Server (not required).

Usage

public deblocking : Number

Description

Property; indicates the type of deblocking filter applied to decoded video as part of postprocessing. Two deblocking filters are available: one in the Sorenson codec and one in the On2 VP6 codec. The following values are acceptable:

0 (the default)--Let the video compressor apply the deblocking filter as needed.
1--Do not use any deblocking filter.
2--Use the Sorenson deblocking filter.
3--Use the On2 deblocking filter and no deringing filter.
4--Use the On2 deblocking and the fast On2 deringing filter.
5--Use the On2 deblocking and the better On2 deringing filter.
6--Same as 5.
7--Same as 5.

If a mode greater than 2 is selected for video when you are using the Sorenson codec, the Sorenson decoder defaults to mode 2 internally.

The deblocking filter has an effect on overall playback performance, and it is usually not necessary for high-bandwidth video. If your system is not powerful enough, you might experience difficulties playing back video with this filter enabled.

Example

The following example plays video1.flv in the my_video Video object, and lets the user change the deblocking filter behavior on video1.flv. Add a Video object called my_video and a ComboBox instance called deblocking_cb to your file, and then add the following ActionScript to your FLA or AS file:

var deblocking_cb:mx.controls.ComboBox;
var my_video:Video; // my_video is a Video object on the Stage.
var my_nc:NetConnection = new NetConnection();
my_nc.connect(null);
var my_ns:NetStream = new NetStream(my_nc);
my_video.attachVideo(my_ns);
my_ns.play("video1.flv");

deblocking_cb.addItem({data:0, label:'Auto'});
deblocking_cb.addItem({data:1, label:'No'});
deblocking_cb.addItem({data:2, label:'Yes'});

var cbListener:Object = new Object();
cbListener.change = function(evt:Object) {
    my_video.deblocking = evt.target.selectedItem.data;
};
deblocking_cb.addEventListener("change", cbListener);

Use the ComboBox instance to change the deblocking filter behavior on video1.flv.