# LocalConnection.connect()

#### Availability

Flash Player 6.

#### Usage

    receiving_lc.connect(connectionName)

#### Parameters

`connectionName` A string that corresponds to the connection name specified in the `LocalConnection.send()` command that wants to communicate with `receiving_lc`.

#### Returns

A Boolean value of `true` if no other process running on the same client machine has already issued this command using the same value for the `connectionName` parameter, `false` otherwise.

#### Description

Method; prepares a LocalConnection object to receive commands from a `LocalConnection.send()` command (called the "sending LocalConnection object"). The object used with this command is called the "receiving LocalConnection object." The receiving and sending objects must be running on the same client machine.

Be sure to define the methods attached to `receiving_lc` before issuing this command, as shown in all the examples in this section.

By default, the Flash Player resolves `connectionName` into a value of `"``subdomain``:connectionName"`, where `subdomain` is the subdomain of the movie containing the `LocalConnection.connect()` command. For example, if the movie containing the receiving LocalConnection object is located at www.someDomain.com, `connectionName` resolves to `"someDomain.com:connectionName"`. (If a movie is located on the client machine, the value assigned to `subdomain` is `"localhost"`.)

Also by default, the Flash Player lets the receiving LocalConnection object accept commands only from sending LocalConnection objects whose connection name also resolves into a value of `"``subdomain``:connectionName"`. In this way, Flash makes it very simple for movies located in the same domain to communicate with each other.

If you are implementing communication only between movies in the same domain, specify a string for `connectionName` that does not begin with an underscore (_) and that does not specify a domain name (for example, `"myDomain:connectionName"`). Use the same string in the `LocalConnection.connect(``connectionName``)` command.

If you are implementing communication between movies located in different domains, see the discussion of `connectionName` in `LocalConnection.send()`, and also the `LocalConnection.allowDomain` and `LocalConnection.domain()` entries.

#### Example

The following example shows how a movie in a particular domain can invoke a method named `Trace` in a receiving movie in the same domain. The receiving movie functions as a trace window for the sending movies; it contains two methods that other movies can call—`Trace` and `Clear`. Buttons pressed in the sending movies call these methods with specified parameters.

    // Receiving movie
    var aLocalConnection = new LocalConnection();
    aLocalConnection.Trace = function(aString)
    {
    	aTextField = aTextField + aString + newline;
    }
    aLocalConnection.Clear = function()
    {
    	aTextField = "";
    }
    aLocalConnection.connect("trace");
    stop();

Movie 1 contains the following code attached to a button labeled PushMe. When you push the button, you see the sentence "The button was pushed." in the receiving movie.

    on (press)
    {
    	var lc = new LocalConnection();
    	lc.send("trace", "Trace", "The button was pushed.");
    	delete lc;
    }

Movie 2 contains an input text box with a var name of `myText`, and the following code attached to a button labeled Copy. When you type some text and then push the button, you see the text you typed in the receiving movie.

    on (press)
    {
    	_parent.lc.send("trace", "Trace", _parent.myText);
    	_parent.myText = "";
    }

Movie 3 contains the following code attached to a button labeled Clear. When you push the button, the contents of the trace window in the receiving movie are cleared (erased).

    on (press)
    {
    	var lc = new LocalConnection();
    	lc.send("trace", "Clear");
    	delete lc;
    }

#### See also

LocalConnection.send()